feat: tenant namespace module

add: proper description explaining the module

fix: change to local variables

Update the label format to  display namespace quota information correctly

Co-authored-by: coderabbitai[bot] <136622811+coderabbitai[bot]@users.noreply.github.com>

fix: add spacing

Author: sathindudezoysa

modules/management/tenant-namespace/main.tf

@@ -0,0 +1,65 @@
+/**
+ * @module management/tenant-namespace
+ * @description Provisions Kubernetes namespaces within a specified Rancher v2 project.
+ * 
+ * ### Features
+ * - Dynamically creates multiple namespaces from a provided list.
+ * - Applies custom labels and annotations for organizational tagging.
+ * - Configures optional container resource limits (CPU/Memory).
+ * - Enforces optional resource quotas (Pods, Storage, LoadBalancers, etc.).
+ * 
+ * ### Prerequisites
+ * 1. **Provider**: Requires the `rancher2` provider authenticated to your Rancher server.
+ * 2. **Project**: You must have a pre-existing Rancher `project_id` to pass as a variable.
+ *
+ */
+
+locals {
+  namespaces = toset(var.namespaces != null ? var.namespaces : [])
+  container_resource_limit = var.container_resource_limit != null ? [var.container_resource_limit] : []
+  resource_quota = var.resource_quota != null ? [var.resource_quota] : []
+}
+
+resource "rancher2_namespace" "this" {
+  for_each = local.namespaces
+
+  name        = each.value
+  project_id  = var.project_id
+  description = var.description
+
+  labels = merge(var.labels, {
+    "field.cattle.io/projectId" = split(":", var.project_id)[1]
+  })
+  annotations      = var.annotations
+  wait_for_cluster = var.wait_for_cluster
+
+  dynamic "container_resource_limit" {
+    for_each = local.container_resource_limit
+    content {
+      limits_cpu      = container_resource_limit.value.cpu_limit
+      limits_memory   = container_resource_limit.value.memory_limit
+      requests_cpu    = container_resource_limit.value.cpu_request
+      requests_memory = container_resource_limit.value.memory_request
+    }
+  }
+
+  dynamic "resource_quota" {
+    for_each = local.resource_quota
+    content {
+      limit {
+        config_maps              = resource_quota.value.config_maps
+        limits_cpu               = resource_quota.value.cpu_limit
+        limits_memory            = resource_quota.value.memory_limit
+        persistent_volume_claims = resource_quota.value.persistent_volume_claims
+        pods                     = resource_quota.value.pods
+        replication_controllers  = resource_quota.value.replication_controllers
+        requests_cpu             = resource_quota.value.cpu_request
+        requests_memory          = resource_quota.value.memory_request
+        requests_storage         = resource_quota.value.storage_request
+        secrets                  = resource_quota.value.secrets
+        services_load_balancers  = resource_quota.value.services_load_balancers
+        services_node_ports      = resource_quota.value.services_node_ports
+      }
+    }
+  }
+}

modules/management/tenant-namespace/outputs.tf

@@ -0,0 +1,9 @@
+output "namespaces" {
+  description = "Map of created rancher2_namespace resources keyed by namespace name."
+  value       = rancher2_namespace.this
+}
+
+output "namespace_ids" {
+  description = "Map of created namespace IDs."
+  value       = { for k, v in rancher2_namespace.this : k => v.id }
+}

modules/management/tenant-namespace/variables.tf

@@ -0,0 +1,70 @@
+variable "project_id" {
+  description = "The Rancher v2 project ID (format: <cluster_id>:<project_id>)"
+  type        = string
+}
+
+variable "namespaces" {
+  description = "List of namespace names to create."
+  type        = any
+
+  validation {
+    condition = can(
+      [for ns in toset(flatten(tolist([var.namespaces]))) : regex("^[a-z0-9]([-a-z0-9]*[a-z0-9])?$", ns)]
+    )
+    error_message = "Namespace names must consist of lowercase alphanumeric characters or '-', and must start and end with an alphanumeric character."
+  }
+}
+
+variable "description" {
+  description = "Optional description applied to all created namespaces."
+  type        = string
+  default     = null
+}
+
+variable "labels" {
+  description = "Labels to apply to the namespaces."
+  type        = map(string)
+  default     = {}
+}
+
+variable "annotations" {
+  description = "Annotations to apply to the namespaces."
+  type        = map(string)
+  default     = {}
+}
+
+variable "wait_for_cluster" {
+  description = "Wait for cluster to become active before creating namespaces."
+  type        = bool
+  default     = false
+}
+
+variable "container_resource_limit" {
+  description = "Default container resource limits for workloads in these namespaces."
+  type = object({
+    cpu_limit      = optional(string)
+    memory_limit   = optional(string)
+    cpu_request    = optional(string)
+    memory_request = optional(string)
+  })
+  default = null
+}
+
+variable "resource_quota" {
+  description = "Resource quotas applied to each namespace."
+  type = object({
+    config_maps              = optional(string)
+    cpu_limit               = optional(string)
+    memory_limit            = optional(string)
+    persistent_volume_claims = optional(string)
+    pods                     = optional(string)
+    replication_controllers  = optional(string)
+    cpu_request             = optional(string)
+    memory_request          = optional(string)
+    storage_request         = optional(string)
+    secrets                  = optional(string)
+    services_load_balancers  = optional(string)
+    services_node_ports      = optional(string)
+  })
+  default = null
+}

modules/management/tenant-namespace/versions.tf

@@ -0,0 +1,18 @@
+terraform {
+  required_version = ">= 1.5"
+  required_providers {
+    rancher2 = {
+      source  = "rancher/rancher2"
+      version = "~> 13.1"
+    }
+    harvester = {
+      source  = "harvester/harvester"
+      version = "~> 1.7"
+    }
+    kubernetes = {
+      source                = "hashicorp/kubernetes"
+      version               = "~> 2.35"
+      configuration_aliases = [kubernetes.harvester]
+    }
+  }
+}