FrameX-kit/flake.nix at master · touale/FrameX-kit · GitHub

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
{
  description = "Minimal Cargo dev shell for ./book subproject";

  inputs = {
    nixpkgs.url = "github:NixOS/nixpkgs/nixpkgs-unstable";
    rust-overlay.url = "github:oxalica/rust-overlay";
    flake-utils.url = "github:numtide/flake-utils";
  };

  outputs = { self, nixpkgs, rust-overlay, flake-utils, ... }:
    flake-utils.lib.eachDefaultSystem (system:
      let
        pkgs = import nixpkgs {
          inherit system;
          overlays = [ rust-overlay.overlays.default ];
        };

        rustToolchain = pkgs.rust-bin.fromRustupToolchainFile ./book/rust-toolchain.toml;

        mdbook = pkgs.rustPlatform.buildRustPackage rec {
          pname = "mdbook";
          version = "0.5.3";
          src = pkgs.fetchCrate {
            inherit pname version;
            hash = "sha256-2j22rRehYPpyPk1REPhHnRZ05WP0KXcv5mlpMxC83yg=";
          };
          cargoLock.lockFile = "${src}/Cargo.lock";
          doCheck = false;
        };

        mdbookKatex = pkgs.rustPlatform.buildRustPackage rec {
          pname = "mdbook-katex";
          version = "0.10.0-alpha";
          src = pkgs.fetchCrate {
            inherit pname version;
            hash = "sha256-F6ozNlN8umagAWr+xeA61uf+QOae/y6VnyzWKDsFIhk=";
          };
          cargoLock.lockFile = "${src}/Cargo.lock";
        };

        mdbookToc = pkgs.rustPlatform.buildRustPackage rec {
          pname = "mdbook-toc";
          version = "0.15.4";
          src = pkgs.fetchCrate {
            inherit pname version;
            hash = "sha256-sCnHbIQQW7Xc2Z0w3auwx2ZsZ+gEU3tEJZ3Jk65K1cw=";
          };
          cargoLock.lockFile = "${src}/Cargo.lock";
          doCheck = false;
        };
      in
      {
        devShells.default = pkgs.mkShell {
          packages = [
            rustToolchain
            pkgs.rust-analyzer
            mdbook
            mdbookKatex
            mdbookToc
          ];

          CARGO_TARGET_DIR = "./book/target";

          shellHook = ''
            echo "🚀 Rust dev shell for ./book"
            export PATH=$PATH:$HOME/.cargo/bin
            if [ -d book ]; then
              cd book
              echo "📁 cwd => $(pwd)"
            fi
            rustc --version
            cargo --version
            mdbook --version
          '';
        };
      });
}