stump/flake.nix at main · retmas-gh/stump · GitHub

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
{
  inputs = {
    nixpkgs.url = "nixpkgs";
    flake-utils.url = "github:numtide/flake-utils";
    rust-overlay.url = "github:oxalica/rust-overlay";
    android-nixpkgs.url = "github:tadfisher/android-nixpkgs";
  };

  outputs = { self, nixpkgs, rust-overlay, flake-utils, ... }:
    flake-utils.lib.eachDefaultSystem (system:
      let
        overlays = [ (import rust-overlay) ];
        pkgs = import nixpkgs { inherit system overlays; };
        androidPkgs = import nixpkgs {
          inherit system;
          config = {
            android_sdk.accept_license = true;
            allowUnfree = true;
          };
        };

        libraries = with pkgs; [
          webkitgtk_4_1
          gtk3
          cairo
          gdk-pixbuf
          glib
          dbus
          openssl
        ];

        rustVersion = (builtins.fromTOML (builtins.readFile ./rust-toolchain.toml)).toolchain.channel;
        rustToolchain = pkgs.rust-bin.stable.${rustVersion}.default.override {
          extensions = [ "rust-src" "rust-analyzer" ];
        };

        packages = with pkgs; [
          git

          # node
          (nodePackages.yarn.override { withNode = false; })
          nodejs_22

          # rust
          rustToolchain
          cargo-deny
          cargo-edit
          cargo-watch
          bacon

          # Tauri deps
          curl
          wget
          pkg-config
          dbus
          openssl
          glib
          gtk3
          webkitgtk_4_1
        ];

        genericShellConfig = {
          buildInputs = packages;

          RUST_SRC_PATH = "${rustToolchain}/lib/rustlib/src/rust/library";

          shellHook = ''
            export LD_LIBRARY_PATH=${
              pkgs.lib.makeLibraryPath libraries
            }:$LD_LIBRARY_PATH
          '';
        };

        # android setup
        pinnedJDK = androidPkgs.jdk17;
        androidComposition = androidPkgs.androidenv.composeAndroidPackages {
          buildToolsVersions = [ "35.0.0" "36.0.0" ];
          platformVersions = [ "35" "36" ];
          cmakeVersions = [ "3.10.2" "3.22.1" ];
          includeNDK = true;
          ndkVersions = [ "27.0.12077973" "27.1.12297006" ];
        };
        androidSdk = androidComposition.androidsdk;

        android-sdk-root =
          "${androidComposition.androidsdk}/libexec/android-sdk";

        androidPackages =
          (with androidPkgs; [ pinnedJDK androidSdk pkg-config ]);
        androidLibraries = (with androidPkgs; [ libxml2.out ]);

      in {
        devShells.default = pkgs.mkShell genericShellConfig;

        devShells.android = pkgs.mkShell (genericShellConfig // {
          buildInputs = genericShellConfig.buildInputs ++ androidPackages;

          JAVA_HOME = pinnedJDK;
          JAVA_OPTS = "-Xms8g -Xmx8g";
          ANDROID_HOME =
            "${androidComposition.androidsdk}/libexec/android-sdk";
          ANDROID_SDK_ROOT =
            "${androidComposition.androidsdk}/libexec/android-sdk";
          ANDROID_NDK_ROOT = "${android-sdk-root}/ndk-bundle";

          shellHook = ''
            export LD_LIBRARY_PATH=${
              pkgs.lib.makeLibraryPath (libraries ++ androidLibraries)
            }:$LD_LIBRARY_PATH
          '';
        });

      });
}