lambda-version-ref.pkl

/*
 * © 2025 Platform Engineering Labs Inc.
 *
 * SPDX-License-Identifier: FSL-1.1-ALv2
 */

amends "@formae/forma.pkl"
import "@formae/formae.pkl"

import "@aws/aws.pkl"

import "@aws/iam/role.pkl"
import "@aws/lambda/func.pkl"
import "@aws/lambda/permission.pkl"
import "@aws/lambda/version.pkl"

local testRunID = read("env:FORMAE_TEST_RUN_ID")
local stackName = "plugin-sdk-test-lambda-version-ref-\(testRunID)"

local lambdaRole = new role.Role {
  label = "lambda-execution-role"
  roleName = "formae-sdk-test-lambda-vref-role-\(testRunID)"
  assumeRolePolicyDocument {
    ["Version"] = "2012-10-17"
    ["Statement"] {
      new {
        ["Effect"] = "Allow"
        ["Principal"] {
          ["Service"] = "lambda.amazonaws.com"
        }
        ["Action"] = "sts:AssumeRole"
      }
    }
  }
}

local testFunction = new func.Function {
  label = "test-function-for-version-ref"
  functionName = "formae-sdk-test-lambda-vref-\(testRunID)"
  role = lambdaRole.res.arn
  runtime = "python3.12"
  handler = "index.handler"
  code = new func.Code {
    zipFile = """
      import json
      def handler(event, context):
          return {
              'statusCode': 200,
              'body': json.dumps({'message': 'hello from formae'})
          }
      """
  }
  memorySize = 128
  timeout = 10
}

local testVersion = new version.Version {
  label = "plugin-sdk-test-lambda-version-ref"
  functionName = testFunction.res.arn
  description = "Plugin SDK test version for resolvable reference"
}

forma {
  new formae.Stack {
    label = stackName
    description = "Plugin SDK test for Lambda Version references"
  }

  new formae.Target {
    label = "aws-target"
    config = new aws.Config {
      region = "us-east-1"
    }
  }

  lambdaRole

  testFunction

  testVersion

  // The permission targets the published version's qualified ARN, so the
  // apply only succeeds if the Version's FunctionArn resolves.
  new permission.Permission {
    label = "plugin-sdk-test-lambda-version-ref-permission"
    functionName = testVersion.res.functionArn
    action = "lambda:InvokeFunction"
    principal = "apigateway.amazonaws.com"
  }
}