Repository navigation
Expand file tree
/
Copy pathset.os
More file actions
127 lines (100 loc) · 3.25 KB
/
Copy pathset.os
File metadata and controls
127 lines (100 loc) · 3.25 KB
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
!
! BRACY/SET. Sets of small nonnegative integers.
!
! Copyright © 2014 James B. Moen.
!
! This program is free software: you can redistribute it and/or modify it
! under the terms of the GNU General Public License as published by the Free
! Software Foundation, either version 3 of the License, or (at your option)
! any later version.
!
! This program is distributed in the hope that it will be useful, but WITHOUT
! ANY WARRANTY; without even the implied warranty of MERCHANTABILITY or
! FITNESS FOR A PARTICULAR PURPOSE. See the GNU General Public License for
! more details.
!
! You should have received a copy of the GNU General Public License along with
! this program. If not, see <http://www.gnu.org/licenses/>.
!
(prog
! SET. A set of zero or more elements that fit in an INT.
set :− (tuple int Bits)
! ∅. A set with no elements.
set ∅ :−
(with var set self
do self.Bits := 0
self)
! "∪". Return a set like LEFT except that it contains (the elements in) RIGHT.
"∪" :−
(alt
(form (set left, int right) set:
(with var set left :− (past left)
do left ∪= right
left)),
(form (set left, set right) set:
(with var set left :− (past left)
do left ∪= right
left)))
! "∪=". Add (the elements in) RIGHT to the set variable LEFT.
"∪=" :−
(alt
(form (var set left, int right) void:
left.Bits |= 1{int} ← right),
(form (var set left, set right) void:
left.Bits |= right.Bits))
! "−". Return a set like LEFT except that it doesn't contain (the elements in)
! RIGHT.
"−" :−
(alt
(form (set left, int right) set:
(with var set left :− (past left)
do left −= right
left)),
(form (set left, set right) set:
(with var set left :− (past left)
do left −= right
left)))
! "−=". Remove (the elements in) RIGHT from the set variable LEFT.
"−=" :−
(alt
(form (var set left, int right) void:
left.Bits &= ~(1{int} ← right)),
(form (var set left, set right) void:
left.Bits &= ~right.Bits))
! "≠". Test if two sets are not equal.
"≠" :−
(form (set left, set right) bool:
left.Bits ≠ right.Bits)
! "=". Test if two sets are equal.
"=" :−
(form (set left, set right) bool:
left.Bits = right.Bits)
! " {}". Cast the set LEFT to an INT.
" {}" :−
(form (set left, type int) int:
left.Bits)
! "∊". Test if the element LEFT is in the set RIGHT.
"∊" :−
(form (int left, set right) bool:
right.Bits & (1{int} ← left) ≠ 0)
! ELEMENTS. Iterator. Call BODY on each element E in the set S.
elements :−
(form (set s) foj:
(form (form (int) obj body) obj:
(for int e in 0, limit(set)
do (if e ∊ s
then body(e)))))
! LIMIT. Return the maximum element that can fit in a set, a constant.
limit :−
(form (type set) inj:
8 × size(set.Bits) − 1)
! MAKE SET. Return a new set containing integers in the list R.
makeSet :−
(form (list r) set:
(with var set s :− ∅
do (for obj e, list r in tails(isInt, r)
do (if 0 ≤ e ≤ limit(set)
then s ∪= e
else error(r, "out of range")))
s))
)