manatee/build.gradle at master · madislm/manatee · GitHub

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
plugins {
    id 'org.springframework.boot' version '3.2.3'
    id 'io.spring.dependency-management' version '1.0.14.RELEASE'
    id 'org.openapi.generator' version '7.4.0'
    id 'java'
    id 'jacoco'
}

group = 'ee.cyber'
version = '1.0.0'
sourceCompatibility = '21'

configurations {
    compileOnly {
        extendsFrom annotationProcessor
    }
}

repositories {
    mavenCentral()
    maven { url 'https://repo.spring.io/milestone' }
    maven { url 'https://repo.spring.io/snapshot' }
}

dependencies {
    implementation 'org.springframework.boot:spring-boot-starter-data-jpa'
    implementation 'org.springframework.boot:spring-boot-starter-validation'
    implementation 'org.springframework.boot:spring-boot-starter-web'
    implementation 'org.springframework.statemachine:spring-statemachine-core:2.2.0.RELEASE'
    implementation 'org.apache.commons:commons-csv:1.9.0'
    implementation 'org.mapstruct:mapstruct:1.5.3.Final'

    compileOnly 'org.projectlombok:lombok'

    runtimeOnly 'com.h2database:h2'

    annotationProcessor 'org.projectlombok:lombok'
    annotationProcessor 'org.mapstruct:mapstruct-processor:1.5.3.Final'

    testImplementation 'org.springframework.boot:spring-boot-starter-test'
    testCompileOnly 'org.projectlombok:lombok'
    testAnnotationProcessor 'org.projectlombok:lombok'
}

sourceSets {
    main {
        java {
            srcDir 'src/main/java'
            srcDir 'generated-sources/src/main/java'
        }
    }
}

def openapiSpecList = [
        "manatee-api.yaml".toString(),
]

import org.openapitools.generator.gradle.plugin.tasks.GenerateTask

openapiSpecList.each {
    def apiName = it.replace(".yaml", "")
    def taskName = "generate" + apiName.capitalize()
    tasks.register(taskName, GenerateTask.class, {
        generatorName = "spring"

        inputSpec = "$rootDir/spec/".toString() + "${apiName}.yaml"
        outputDir = "$rootDir/generated-sources".toString()

        apiPackage = "ee.cyber.manatee.api"
        modelPackage = "ee.cyber.manatee.dto"
        modelNameSuffix = "Dto"

        generateApiTests = false
        generateApiDocumentation = false

        generateModelTests = false
        generateModelDocumentation = false

        verbose = false
        skipOverwrite = false

        configOptions = [
                dateLibrary            : "java8",
                documentationProvider  : "none",
                hideGenerationTimestamp: "true",
                additionalModelTypeAnnotations: "@lombok.Builder; @lombok.AllArgsConstructor",
                useOptional            : "true",
                useSwaggerUI           : "true",
                delegatePattern        : "false",
                interfaceOnly          : "true",
                useTags                : "true",
                openApiNullable        : "false",
                useSpringBoot3         : "true",
                title                  : "Manatee API",
        ]
    })

    tasks.named(taskName) {
        doLast {
            delete "$rootDir/generated-sources/.openapi-generator"
            delete "$rootDir/generated-sources/src/test"
            delete "$rootDir/generated-sources/src/main/resources"
            delete "$rootDir/generated-sources/src/main/java/org"
            delete "$rootDir/generated-sources/.openapi-generator-ignore"
            delete "$rootDir/generated-sources/pom.xml"
            delete "$rootDir/generated-sources/README.md"
        }
    }
    compileJava.dependsOn(taskName)
}


tasks.named('test') {
    useJUnitPlatform()
}

jacocoTestReport {
    dependsOn test // tests are required to run before generating the report

    afterEvaluate {
        classDirectories.setFrom(files(classDirectories.files.collect {
            fileTree(dir: it, exclude: [
                    "ee/cyber/manatee/api/*",
                    "ee/cyber/manatee/dto/*",
                    "ee/cyber/manatee/mapper/*",
                    "ee/cyber/manatee/model/*",
            ])
        }))
    }
}