flake.nix

{
  description = "A library and client implementation of luarocks";

  nixConfig = {
    extra-substituters = "https://neorocks.cachix.org";
    extra-trusted-public-keys = "neorocks.cachix.org-1:WqMESxmVTOJX7qoBC54TwrMMoVI1xAM+7yFin8NRfwk=";
  };

  inputs = {
    nixpkgs.url = "github:NixOS/nixpkgs/nixos-unstable";
    crane.url = "github:ipetkov/crane";
    flake-parts.url = "github:hercules-ci/flake-parts";
    git-hooks = {
      url = "github:cachix/git-hooks.nix";
      inputs.nixpkgs.follows = "nixpkgs";
    };
  };

  outputs = inputs @ {
    self,
    nixpkgs,
    flake-parts,
    git-hooks,
    ...
  }:
    flake-parts.lib.mkFlake {inherit inputs;} {
      systems = builtins.attrNames nixpkgs.legacyPackages;
      perSystem = attrs @ {
        system,
        pkgs,
        ...
      }: let
        pkgs = attrs.pkgs.extend self.overlays.default;
        lib = pkgs.lib;
        rockspecTests = pkgs.callPackage ./nix/tests/rockspec.nix {};
        nvimPluginTests = pkgs.callPackage ./nix/tests/nvim-plugin.nix {};
        luxProjectTests = pkgs.callPackage ./nix/tests/lux-project.nix {};
        buildLuxHelpersTests = pkgs.callPackage ./nix/tests/build-lux-helpers.nix {};
        git-hooks-check = git-hooks.lib.${system}.run {
          src = self;
          hooks = {
            # NOTE: When adding/removing hooks, make sure
            # to update CONTRIBUTING.md for non-nix users.
            alejandra.enable = true;
            rustfmt.enable = true;
            taplo = {
              enable = true;
              name = "taplo";
              description = "Format TOML files with taplo fmt";
              extraPackages = [pkgs.taplo];
              entry = "taplo fmt";
              types = ["toml"];
              excludes = ["lux-workspace-hack/Cargo.toml"];
            };
          };
        };
      in {
        packages = with pkgs; {
          default = lux-cli;
          inherit
            lux-cli
            lux-lsp
            lux-lua51
            lux-lua52
            lux-lua53
            lux-lua54
            lux-lua55
            lux-luajit
            ;
        };

        legacyPackages = pkgs;

        devShells = let
          isDarwin = pkgs.stdenv.isDarwin;
          mkDevShell = extra_pkgs:
            pkgs.mkShell {
              name = "lux devShell";
              shellHook =
                lib.optionalString
                (!isDarwin)
                git-hooks-check.shellHook;
              buildInputs =
                extra_pkgs
                ++ (with pkgs; [
                  rust-analyzer
                  lspmux
                  cargo-nextest
                  cargo-hakari
                  cargo-insta
                  cargo-cross
                  clippy
                  taplo
                  # Needed for integration test builds
                  pkg-config
                  libxcrypt
                  cmakeMinimal
                  zlib
                  gnum4
                ])
                ++ (lib.optional (!isDarwin) self.checks.${system}.git-hooks-check.enabledPackages)
                ++ (lib.filter (pkg: !(lib.hasPrefix "lua" pkg.name)) pkgs.lux-cli.buildInputs)
                ++ (lib.filter (pkg: !(lib.hasPrefix "xtask" pkg.name)) pkgs.lux-cli.nativeBuildInputs);
            };

          mkBuildShell = pkgs':
            pkgs'.mkShell {
              name = "lux buildShell";
              buildInputs =
                (lib.filter (pkg: !(lib.hasPrefix "lua" pkg.name)) pkgs'.lux-cli.buildInputs)
                ++ pkgs'.lux-cli.nativeBuildInputs;
            };
        in rec {
          default = lua51;

          lua51 = mkDevShell [pkgs.lua5_1];
          lua52 = mkDevShell [pkgs.lua5_2];
          lua53 = mkDevShell [pkgs.lua5_3];
          lua54 = mkDevShell [pkgs.lua5_4];
          lua55 = mkDevShell [pkgs.lua5_5];
          luajit = mkDevShell [pkgs.luajit];

          # devShells with neovim-unwrapped (for CI integration tests)
          lua51-ci = mkDevShell (with pkgs; [lua5_1 neovim-unwrapped]);
          lua52-ci = mkDevShell (with pkgs; [lua5_2 neovim-unwrapped]);
          lua53-ci = mkDevShell (with pkgs; [lua5_3 neovim-unwrapped]);
          lua54-ci = mkDevShell (with pkgs; [lua5_4 neovim-unwrapped]);
          lua55-ci = mkDevShell (with pkgs; [lua5_5 neovim-unwrapped]);
          luajit-ci = mkDevShell (with pkgs; [luajit neovim-unwrapped]);

          cd = mkBuildShell pkgs;
        };

        checks = rec {
          default = tests;
          inherit
            git-hooks-check
            ;
          tests = pkgs.lux-nextest;
          lua-tests = pkgs.lux-nextest-lua;
          clippy = pkgs.lux-clippy;
          workspace-hack = pkgs.lux-workspace-hack;
          rockspec-cjson = rockspecTests.cjson;
          rockspec-luassert = rockspecTests.luassert;
          rockspec-toml-edit = rockspecTests.toml-edit;
          nvim-plugin = nvimPluginTests.test;
          nvim-plugin-luxHash = nvimPluginTests.test-luxHash;
          lux-project-toml-edit = luxProjectTests.test;
          build-lux-helpers = buildLuxHelpersTests.fetchLuxDeps;
          build-lux-helpers-import-lock = buildLuxHelpersTests.importLuxLock;
          build-lux-helpers-lux-lock = buildLuxHelpersTests.luxLock;
          build-lux-helpers-lux-vendor-dir = buildLuxHelpersTests.luxVendorDir;
          build-lux-helpers-with-packages = buildLuxHelpersTests.withPackages;
        };

        formatter = let
          config = self.checks.${system}.git-hooks-check.config;
          inherit (config) package configFile;
          script = ''
            ${pkgs.lib.getExe package} run --all-files --config ${configFile}
          '';
        in
          pkgs.writeShellScriptBin "pre-commit-run" script;
      };
      flake = {
        overlays.default = with inputs; import ./nix/overlay.nix {inherit self crane;};
      };
    };
}