added subcat functions

Author: jishnub

Project.toml

@@ -1,16 +1,18 @@
 name = "ParallelUtilities"
 uuid = "fad6cfc8-4f83-11e9-06cc-151124046ad0"
-authors = ["Jishnu Bhattacharya <[email protected]>"]
-version = "0.7.5"
+authors = ["Jishnu Bhattacharya"]
+version = "0.7.6"
 
 [deps]
 DataStructures = "864edb3b-99cc-5e75-8d2d-829cb0a9cfe8"
 Distributed = "8ba89e20-285c-5b6f-9357-94700520ee1b"
+OffsetArrays = "6fe1bfb0-de20-5000-8ca7-80f57d26f881"
 ProgressMeter = "92933f4c-e287-5a05-a399-4b506db050ca"
 Reexport = "189a3867-3050-52da-a836-e630ba90ab69"
 
 [compat]
 DataStructures = "0.17, 0.18"
+OffsetArrays = "1"
 ProgressMeter = "1.2"
 Reexport = "0.2"
 julia = "1.2"

docs/make.jl

@@ -14,7 +14,7 @@ makedocs(;
         assets=String[],
     ),
     pages=[
-        "Reference" => "index.md",
+        "API" => "index.md",
     ],
 )
 

src/ParallelUtilities.jl

@@ -2,6 +2,7 @@ module ParallelUtilities
 using ProgressMeter
 using DataStructures
 using Reexport
+using OffsetArrays
 @reexport using Distributed
 
 export  ProductSplit,
@@ -28,5 +29,6 @@ include("productsplit.jl")
 include("utils.jl")
 include("trees.jl")
 include("mapreduce.jl")
+include("reductionfunctions.jl")
 
 end # module

src/reductionfunctions.jl

@@ -0,0 +1,200 @@
+throw_dimserror(dims::Integer, N) = throw(ArgumentError("dims = $dims does not satisfy 1 <= dims <= $N"))
+throw_dimserror(dims, N) = throw(ArgumentError("dims = $dims does not satisfy 1 <= dims <= $N for all elements"))
+
+throw_axesmismatcherror(dim, axexp, axrcv) = throw(
+	DimensionMismatch("axes mismatch in dimension $dim, expected $axexp but received $axrcv"))
+
+function _checkdims(A, dim, ax_exp)
+	for a in A
+		axadim = axes(a, dim)
+		if axadim != ax_exp
+			throw_axesmismatcherror(dim, ax_exp, axadim)
+		end
+	end
+end
+
+function checkdims(A, dims)
+	for (dim, ax_exp) in enumerate(axes(first(A)))
+		if dim ∉ dims
+			_checkdims(A, dim, ax_exp)
+		end
+	end
+end
+
+function checkdims(A, d::Integer)
+	for (dim, ax_exp) in enumerate(axes(first(A)))
+		dim == d && continue
+		_checkdims(A, dim, ax_exp)
+	end
+end
+
+"""
+	ParallelUtilities.sumcat_aligned(A::AbstractArray{T,N}...; dims) where {T,N}
+
+Concatenate the arrays along the dimensions `dims` according to their axes, 
+with overlapping sections being summed over. Returns an `OffsetArray` with the minimal 
+axes span encompassing all the arrays.
+
+`dims` may be an `Integer` or a collection of `Integer`s, but all elements of `dims` must be from the range `1:N`.
+
+# Examples
+```jldoctest
+julia> ParallelUtilities.sumcat_aligned(ones(1:2), ones(4:5), dims=1)
+5-element OffsetArray(::Array{Float64,1}, 1:5) with eltype Float64 with indices 1:5:
+ 1.0
+ 1.0
+ 0.0
+ 1.0
+ 1.0
+
+julia> ParallelUtilities.sumcat_aligned(ones(1:2, 1:2), ones(2:3, 2:3), dims=(1,2))
+3×3 OffsetArray(::Array{Float64,2}, 1:3, 1:3) with eltype Float64 with indices 1:3×1:3:
+ 1.0  1.0  0.0
+ 1.0  2.0  1.0
+ 0.0  1.0  1.0
+
+julia> ParallelUtilities.sumcat_aligned(ones(1:2, 1:2), ones(3:4, 3:4), dims=(1,2))
+4×4 OffsetArray(::Array{Float64,2}, 1:4, 1:4) with eltype Float64 with indices 1:4×1:4:
+ 1.0  1.0  0.0  0.0
+ 1.0  1.0  0.0  0.0
+ 0.0  0.0  1.0  1.0
+ 0.0  0.0  1.0  1.0
+```
+
+See also: [`sumhcat_aligned`](@ref), [`sumvcat_aligned`](@ref)
+"""
+function sumcat_aligned(A::AbstractArray{T,N}...; dims) where {T,N}
+
+	all(x -> 1 <= x <= N, dims) || throw_dimserror(dims, N)
+
+	checkdims(A, dims)
+
+	ax = Vector{UnitRange{Int}}(undef, N)
+	ax .= axes(first(A))
+
+	for d in dims
+		axmin = minimum(minimum.(axes.(A, d)))
+		axmax = maximum(maximum.(axes.(A, d)))
+		ax[d] = axmin:axmax
+	end
+	
+	arr = OffsetArray{T,N}(undef, ax...)
+	fill!(arr, zero(T))
+
+	for a in A
+		arr[axes(a)...] .+= a
+	end
+	arr
+end
+
+sumcat_aligned(A1::AbstractArray; dims) = (all(x -> 1 <= x <= ndims(A1), dims) || throw_dimserror(dims); A1)
+
+"""
+	ParallelUtilities.sumvcat_aligned(A::AbstractArray{T,N}...) where {T,N}
+
+Concatenate the arrays along the first dimension according to their axes, 
+with overlapping sections being summed over. Returns an `OffsetArray` with the minimal 
+axes span encompassing all the arrays.
+
+The input arrays must be at least one-dimensional.
+
+# Examples
+```jldoctest
+julia> ParallelUtilities.sumvcat_aligned(ones(1:2), ones(4:5))
+5-element OffsetArray(::Array{Float64,1}, 1:5) with eltype Float64 with indices 1:5:
+ 1.0
+ 1.0
+ 0.0
+ 1.0
+ 1.0
+
+julia> ParallelUtilities.sumvcat_aligned(ones(1:2, 1:2), ones(2:3, 1:2))
+3×2 OffsetArray(::Array{Float64,2}, 1:3, 1:2) with eltype Float64 with indices 1:3×1:2:
+ 1.0  1.0
+ 2.0  2.0
+ 1.0  1.0
+```
+
+See also: [`sumcat_aligned`](@ref), [`sumhcat_aligned`](@ref)
+"""
+function sumvcat_aligned(A::AbstractArray{T,N}...) where {T,N}
+
+	N >= 1 || throw(ArgumentError("all the arrays need to have at least 1 dimension"))
+	checkdims(A, 1)
+
+	axmin = minimum(minimum.(axes.(A, 1)))
+	axmax = maximum(maximum.(axes.(A, 1)))
+	
+	axcat = axmin:axmax
+
+	trailing_axes = Base.tail(axes(first(A)))
+	
+	arr = OffsetArray{T,N}(undef, axcat, trailing_axes...)
+	fill!(arr, zero(T))
+
+	for axt in CartesianIndices(trailing_axes)
+		for a in A, ind1 in axes(a,1)
+			arr[ind1, axt] += a[ind1, axt]
+		end
+	end
+
+	arr
+end
+
+function sumvcat_aligned(A::AbstractArray)
+	ndims(A) >= 1 || throw(ArgumentError("the array needs to have at least 1 dimension"))
+	A
+end
+
+"""
+	ParallelUtilities.sumhcat_aligned(A::AbstractArray{T,N}...) where {T,N}
+
+Concatenate the arrays along the second dimension according to their axes, 
+with overlapping sections being summed over. Returns an `OffsetArray` with the minimal 
+axes span encompassing all the arrays. 
+
+The input arrays must be at least two-dimensional.
+
+# Examples
+```jldoctest
+julia> ParallelUtilities.sumhcat_aligned(ones(2, 1:2), ones(2, 4:5))
+2×5 OffsetArray(::Array{Float64,2}, 1:2, 1:5) with eltype Float64 with indices 1:2×1:5:
+ 1.0  1.0  0.0  1.0  1.0
+ 1.0  1.0  0.0  1.0  1.0
+
+julia> ParallelUtilities.sumhcat_aligned(ones(1:2, 1:2), ones(1:2, 2:3))
+2×3 OffsetArray(::Array{Float64,2}, 1:2, 1:3) with eltype Float64 with indices 1:2×1:3:
+ 1.0  2.0  1.0
+ 1.0  2.0  1.0
+```
+
+See also: [`sumcat_aligned`](@ref), [`sumvcat_aligned`](@ref)
+"""
+function sumhcat_aligned(A::AbstractArray{T,N}...) where {T,N}
+
+	N >= 2 || throw(ArgumentError("all the arrays need to have at least 2 dimensions"))
+	checkdims(A, 2)
+
+	axmin = minimum(minimum.(axes.(A, 2)))
+	axmax = maximum(maximum.(axes.(A, 2)))
+	
+	axcat = axmin:axmax
+
+	trailing_axes = Base.tail(Base.tail(axes(first(A))))
+	
+	arr = OffsetArray{T,N}(undef, axes(first(A),1), axcat, trailing_axes...)
+	fill!(arr, zero(T))
+
+	for axt in CartesianIndices(trailing_axes)
+		for a in A, ind2 in axes(a,2), ind1 in axes(a,1)
+			arr[ind1, ind2, axt] += a[ind1, ind2, axt]
+		end
+	end
+
+	arr
+end
+
+function sumhcat_aligned(A::AbstractArray)
+	ndims(A) >= 2 || throw(ArgumentError("the array needs to have at least 2 dimensions"))
+	A
+end