(Unnecessary?) overlapping instance for `WithStatus`

[alpmestan]

An overlapping instance related compilation error brought up by @Taneb on IRC made me wonder about

instance {-# OVERLAPPING #-} MimeRender JSON a => MimeRender JSON (WithStatus _status a) where
  mimeRender contentTypeProxy (WithStatus a) = mimeRender contentTypeProxy a

It just seems giving FromJSON/ToJSON instances to WithStatus would be the better move here, just delegating the JSON encoding/decoding to the wrapped a, since the status is irrelevant as far as JSON encoding is concerned. Some discussion could be held for the other content types where we don't have a "standard encoding/decoding rule", so to speak.

The instance above is at least better than that of a previous servant release where we had the too-general instance MimeRender ctype a => instance MimeRender ctype (WithStatus _status a), which ended up biting @Taneb. But it still feels like the instance mentioned at the beginning could better be done by specifying ToJSON/FromJSON for WithStatus instead, which would allow us to avoid an overlapping instance, which often is an occasion to trigger compilation errors waiting to happen.

[alpmestan]

I've been bitten by this just now.

[alpmestan]

diff --git a/servant/src/Servant/API/UVerb.hs b/servant/src/Servant/API/UVerb.hs
index ed59eded..1d1fb132 100644
--- a/servant/src/Servant/API/UVerb.hs
+++ b/servant/src/Servant/API/UVerb.hs
@@ -33,12 +33,14 @@ module Servant.API.UVerb
   )
 where
 
+import Data.Aeson
 import Data.Proxy (Proxy (Proxy))
 import GHC.TypeLits (Nat)
 import Network.HTTP.Types (Status, StdMethod)
 import Servant.API.ContentTypes (JSON, PlainText, FormUrlEncoded, OctetStream, NoContent, MimeRender(mimeRender), MimeUnrender(mimeUnrender))
 import Servant.API.Status (KnownStatus, statusVal)
 import Servant.API.UVerb.Union
+import Web.FormUrlEncoded
 
 class KnownStatus (StatusOf a) => HasStatus (a :: *) where
   type StatusOf (a :: *) :: Nat
@@ -99,26 +101,26 @@ instance KnownStatus n => HasStatus (WithStatus n a) where
 -- use 'respond' instead of 'pure' or 'return', so all old handlers would have to be rewritten.
 data UVerb (method :: StdMethod) (contentTypes :: [*]) (as :: [*])
 
-instance {-# OVERLAPPING #-} MimeRender JSON a => MimeRender JSON (WithStatus _status a) where
-  mimeRender contentTypeProxy (WithStatus a) = mimeRender contentTypeProxy a
+instance ToJSON a => ToJSON (WithStatus _status a) where
+  toJSON (WithStatus a) = toJSON a
 
 instance {-# OVERLAPPING #-} MimeRender PlainText a => MimeRender PlainText (WithStatus _status a) where
   mimeRender contentTypeProxy (WithStatus a) = mimeRender contentTypeProxy a
 
-instance {-# OVERLAPPING #-} MimeRender FormUrlEncoded a => MimeRender FormUrlEncoded (WithStatus _status a) where
-  mimeRender contentTypeProxy (WithStatus a) = mimeRender contentTypeProxy a
+instance ToForm a => ToForm (WithStatus _status a) where
+  toForm (WithStatus a) = toForm a
 
 instance {-# OVERLAPPING #-} MimeRender OctetStream a => MimeRender OctetStream (WithStatus _status a) where
   mimeRender contentTypeProxy (WithStatus a) = mimeRender contentTypeProxy a
 
-instance {-# OVERLAPPING #-} MimeUnrender JSON a => MimeUnrender JSON (WithStatus _status a) where
-  mimeUnrender contentTypeProxy input = WithStatus <$> mimeUnrender contentTypeProxy input
+instance FromJSON a => FromJSON (WithStatus _status a) where
+  parseJSON v = WithStatus <$> parseJSON v
 
 instance {-# OVERLAPPING #-} MimeUnrender PlainText a => MimeUnrender PlainText (WithStatus _status a) where
   mimeUnrender contentTypeProxy input = WithStatus <$> mimeUnrender contentTypeProxy input
 
-instance {-# OVERLAPPING #-} MimeUnrender FormUrlEncoded a => MimeUnrender FormUrlEncoded (WithStatus _status a) where
-  mimeUnrender contentTypeProxy input = WithStatus <$> mimeUnrender contentTypeProxy input
+instance FromForm a => FromForm (WithStatus _status a) where
+  fromForm v = WithStatus <$> fromForm v
 
 instance {-# OVERLAPPING #-} MimeUnrender OctetStream a => MimeUnrender OctetStream (WithStatus _status a) where
   mimeUnrender contentTypeProxy input = WithStatus <$> mimeUnrender contentTypeProxy input

might be a good start, since we're explicitly tying rendering of JSON and form encoded values to the corresponding classes, while we don't have such classes for plain text and octet stream IIRC.

[fisx]

UVerb is deprecated. if this issue applies to MultiVerb, please open another issue.