|
| 1 | +/** |
| 2 | + * Provides classes and predicates for reasoning about cross-site scripting (XSS) |
| 3 | + * vulnerabilities. |
| 4 | + */ |
| 5 | + |
| 6 | +import rust |
| 7 | +private import codeql.rust.dataflow.DataFlow |
| 8 | +private import codeql.rust.dataflow.FlowSink |
| 9 | +private import codeql.rust.Concepts |
| 10 | +private import codeql.util.Unit |
| 11 | +private import codeql.rust.security.Barriers as Barriers |
| 12 | + |
| 13 | +/** |
| 14 | + * Provides default sources, sinks and barriers for detecting XSS |
| 15 | + * vulnerabilities, as well as extension points for adding your own. |
| 16 | + */ |
| 17 | +module Xss { |
| 18 | + /** |
| 19 | + * A data flow source for XSS vulnerabilities. |
| 20 | + */ |
| 21 | + abstract class Source extends DataFlow::Node { } |
| 22 | + |
| 23 | + /** |
| 24 | + * A data flow sink for XSS vulnerabilities. |
| 25 | + */ |
| 26 | + abstract class Sink extends QuerySink::Range { |
| 27 | + override string getSinkType() { result = "Xss" } |
| 28 | + } |
| 29 | + |
| 30 | + /** |
| 31 | + * A barrier for XSS vulnerabilities. |
| 32 | + */ |
| 33 | + abstract class Barrier extends DataFlow::Node { } |
| 34 | + |
| 35 | + /** |
| 36 | + * An active threat-model source, considered as a flow source. |
| 37 | + */ |
| 38 | + private class ActiveThreatModelSourceAsSource extends Source, ActiveThreatModelSource { } |
| 39 | + |
| 40 | + /** |
| 41 | + * A sink for XSS from model data. |
| 42 | + */ |
| 43 | + private class ModelsAsDataSink extends Sink { |
| 44 | + ModelsAsDataSink() { sinkNode(this, "html-injection") } |
| 45 | + } |
| 46 | + |
| 47 | + /** |
| 48 | + * A barrier for XSS vulnerabilities for nodes whose type is a |
| 49 | + * numeric or boolean type, which is unlikely to expose any vulnerability. |
| 50 | + */ |
| 51 | + private class NumericTypeBarrier extends Barrier instanceof Barriers::NumericTypeBarrier { } |
| 52 | + |
| 53 | + /** A call to a function with "escape" or "encode" in its name. */ |
| 54 | + private class HeuristicHtmlEncodingBarrier extends Barrier { |
| 55 | + HeuristicHtmlEncodingBarrier() { |
| 56 | + exists(Call fc | |
| 57 | + fc.getStaticTarget().getName().getText().regexpMatch(".*(escape|encode).*") and |
| 58 | + fc.getArgument(_) = this.asExpr() |
| 59 | + ) |
| 60 | + } |
| 61 | + } |
| 62 | +} |
0 commit comments