Add dominoes exercise (#362)

Author: keiravillekode

config.json

@@ -713,6 +713,14 @@
         "prerequisites": [],
         "difficulty": 7
       },
+      {
+        "slug": "dominoes",
+        "name": "Dominoes",
+        "uuid": "d5b502c3-f2f6-47e9-be82-b808bc76e598",
+        "practices": [],
+        "prerequisites": [],
+        "difficulty": 7
+      },
       {
         "slug": "circular-buffer",
         "name": "Circular Buffer",

exercises/practice/dominoes/.docs/instructions.md

@@ -0,0 +1,15 @@
+# Instructions
+
+Make a chain of dominoes.
+
+Compute a way to order a given set of domino stones so that they form a correct domino chain.
+In the chain, the dots on one half of a stone must match the dots on the neighboring half of an adjacent stone.
+Additionally, the dots on the halves of the stones without neighbors (the first and last stone) must match each other.
+
+For example given the stones `[2|1]`, `[2|3]` and `[1|3]` you should compute something
+like `[1|2] [2|3] [3|1]` or `[3|2] [2|1] [1|3]` or `[1|3] [3|2] [2|1]` etc, where the first and last numbers are the same.
+
+For stones `[1|2]`, `[4|1]` and `[2|3]` the resulting chain is not valid: `[4|1] [1|2] [2|3]`'s first and last numbers are not the same.
+4 != 3
+
+Some test cases may use duplicate stones in a chain solution, assume that multiple Domino sets are being used.

exercises/practice/dominoes/.docs/introduction.md

@@ -0,0 +1,13 @@
+# Introduction
+
+In Toyland, the trains are always busy delivering treasures across the city, from shiny marbles to rare building blocks.
+The tracks they run on are made of colorful domino-shaped pieces, each marked with two numbers.
+For the trains to move, the dominoes must form a perfect chain where the numbers match.
+
+Today, an urgent delivery of rare toys is on hold.
+You've been handed a set of track pieces to inspect.
+If they can form a continuous chain, the train will be on its way, bringing smiles across Toyland.
+If not, the set will be discarded, and another will be tried.
+
+The toys are counting on you to solve this puzzle.
+Will the dominoes connect the tracks and send the train rolling, or will the set be left behind?

exercises/practice/dominoes/.meta/config.json

@@ -0,0 +1,17 @@
+{
+  "authors": [
+    "keiravillekode"
+  ],
+  "files": {
+    "solution": [
+      "dominoes.sml"
+    ],
+    "test": [
+      "test.sml"
+    ],
+    "example": [
+      ".meta/example.sml"
+    ]
+  },
+  "blurb": "Make a chain of dominoes."
+}

exercises/practice/dominoes/.meta/example.sml

@@ -0,0 +1,57 @@
+fun canChain (dominoes: (int * int) list): bool =
+  let
+    val n = 7 (* values 0..6 *)
+    val parent = Array.tabulate (n, fn i => i)
+    val size = Array.array (n, 1)
+    val tally = Array.array (n, 0)
+
+    fun increment (arr, i) = Array.update (arr, i, Array.sub (arr, i) + 1)
+
+    fun find x =
+      let
+        val p = Array.sub (parent, x)
+      in
+        if p = x then x
+        else
+          let
+            val gp = Array.sub (parent, p)
+          in
+            Array.update (parent, x, gp);
+            find gp
+          end
+      end
+
+    fun union (a, b) =
+      let
+        val ra = find a
+        val rb = find b
+      in
+        if ra = rb then ()
+        else
+          let
+            val sa = Array.sub (size, ra)
+            val sb = Array.sub (size, rb)
+          in
+            if sa < sb then
+              (Array.update (parent, ra, rb);
+               Array.update (size, rb, sa + sb))
+            else
+              (Array.update (parent, rb, ra);
+               Array.update (size, ra, sa + sb))
+          end
+      end
+
+    val _ = List.app (fn (a, b) => (
+      increment (tally, a);
+      increment (tally, b);
+      union (a, b))) dominoes
+
+    (* Check all vertices have even tally *)
+    val allEven = Array.foldl (fn (d, acc) => acc andalso d mod 2 = 0) true tally
+
+    (* Count roots among vertices with nonzero tally *)
+    val roots = Array.foldli (fn (i, d, acc) =>
+      if d > 0 andalso Array.sub (parent, i) = i then acc + 1 else acc) 0 tally
+  in
+    allEven andalso roots <= 1
+  end

exercises/practice/dominoes/.meta/tests.toml

@@ -0,0 +1,49 @@
+# This is an auto-generated file.
+#
+# Regenerating this file via `configlet sync` will:
+# - Recreate every `description` key/value pair
+# - Recreate every `reimplements` key/value pair, where they exist in problem-specifications
+# - Remove any `include = true` key/value pair (an omitted `include` key implies inclusion)
+# - Preserve any other key/value pair
+#
+# As user-added comments (using the # character) will be removed when this file
+# is regenerated, comments can be added via a `comment` key.
+
+[31a673f2-5e54-49fe-bd79-1c1dae476c9c]
+description = "empty input = empty output"
+
+[4f99b933-367b-404b-8c6d-36d5923ee476]
+description = "singleton input = singleton output"
+
+[91122d10-5ec7-47cb-b759-033756375869]
+description = "singleton that can't be chained"
+
+[be8bc26b-fd3d-440b-8e9f-d698a0623be3]
+description = "three elements"
+
+[99e615c6-c059-401c-9e87-ad7af11fea5c]
+description = "can reverse dominoes"
+
+[51f0c291-5d43-40c5-b316-0429069528c9]
+description = "can't be chained"
+
+[9a75e078-a025-4c23-8c3a-238553657f39]
+description = "disconnected - simple"
+
+[0da0c7fe-d492-445d-b9ef-1f111f07a301]
+description = "disconnected - double loop"
+
+[b6087ff0-f555-4ea0-a71c-f9d707c5994a]
+description = "disconnected - single isolated"
+
+[2174fbdc-8b48-4bac-9914-8090d06ef978]
+description = "need backtrack"
+
+[167bb480-dfd1-4318-a20d-4f90adb4a09f]
+description = "separate loops"
+
+[cd061538-6046-45a7-ace9-6708fe8f6504]
+description = "nine elements"
+
+[44704c7c-3adb-4d98-bd30-f45527cf8b49]
+description = "separate three-domino loops"

exercises/practice/dominoes/dominoes.sml

@@ -0,0 +1,2 @@
+fun canChain (dominoes: (int * int) list): bool =
+  raise Fail "'canChain' is not implemented"

exercises/practice/dominoes/test.sml

@@ -0,0 +1,51 @@
+(* version 1.0.0 *)
+
+use "testlib.sml";
+use "dominoes.sml";
+
+infixr |>
+fun x |> f = f x
+
+val testsuite =
+  describe "dominoes" [
+    test "empty input = empty output"
+      (fn _ => canChain [] |> Expect.truthy),
+
+    test "singleton input = singleton output"
+      (fn _ => canChain [(1, 1)] |> Expect.truthy),
+
+    test "singleton that can't be chained"
+      (fn _ => canChain [(1, 2)] |> Expect.falsy),
+
+    test "three elements"
+      (fn _ => canChain [(1, 2), (3, 1), (2, 3)] |> Expect.truthy),
+
+    test "can reverse dominoes"
+      (fn _ => canChain [(1, 2), (1, 3), (2, 3)] |> Expect.truthy),
+
+    test "can't be chained"
+      (fn _ => canChain [(1, 2), (4, 1), (2, 3)] |> Expect.falsy),
+
+    test "disconnected - simple"
+      (fn _ => canChain [(1, 1), (2, 2)] |> Expect.falsy),
+
+    test "disconnected - double loop"
+      (fn _ => canChain [(1, 2), (2, 1), (3, 4), (4, 3)] |> Expect.falsy),
+
+    test "disconnected - single isolated"
+      (fn _ => canChain [(1, 2), (2, 3), (3, 1), (4, 4)] |> Expect.falsy),
+
+    test "need backtrack"
+      (fn _ => canChain [(1, 2), (2, 3), (3, 1), (2, 4), (2, 4)] |> Expect.truthy),
+
+    test "separate loops"
+      (fn _ => canChain [(1, 2), (2, 3), (3, 1), (1, 1), (2, 2), (3, 3)] |> Expect.truthy),
+
+    test "nine elements"
+      (fn _ => canChain [(1, 2), (5, 3), (3, 1), (1, 2), (2, 4), (1, 6), (2, 3), (3, 4), (5, 6)] |> Expect.truthy),
+
+    test "separate three-domino loops"
+      (fn _ => canChain [(1, 2), (2, 3), (3, 1), (4, 5), (5, 6), (6, 4)] |> Expect.falsy)
+  ]
+
+val _ = Test.run testsuite

exercises/practice/dominoes/testlib.sml

@@ -0,0 +1,160 @@
+structure Expect =
+struct
+  datatype expectation = Pass | Fail of string * string
+
+  local
+    fun failEq b a =
+      Fail ("Expected: " ^ b, "Got: " ^ a)
+    
+    fun failExn b a =
+      Fail ("Expected: " ^ b, "Raised: " ^ a)
+
+    fun exnName (e: exn): string = General.exnName e
+  in
+    fun truthy a =
+      if a
+      then Pass
+      else failEq "true" "false"
+
+    fun falsy a =
+      if a
+      then failEq "false" "true"
+      else Pass
+
+    fun equalTo b a = 
+      if a = b
+      then Pass
+      else failEq (PolyML.makestring b) (PolyML.makestring a)
+
+    fun nearTo delta b a =
+      if Real.abs (a - b) <= delta * Real.abs a orelse
+         Real.abs (a - b) <= delta * Real.abs b
+      then Pass
+      else failEq (Real.toString b ^ " +/- " ^ Real.toString delta) (Real.toString a)
+
+    fun anyError f =
+      (
+        f ();
+        failExn "an exception" "Nothing"
+      ) handle _ => Pass
+
+    fun error e f =
+      (
+        f ();
+        failExn (exnName e) "Nothing"
+      ) handle e' => if exnMessage e' = exnMessage e
+                     then Pass
+                     else failExn (exnMessage e) (exnMessage e')
+  end
+end
+
+structure TermColor =
+struct
+  datatype color = Red | Green | Yellow | Normal
+
+  fun f Red    = "\027[31m"
+    | f Green  = "\027[32m"
+    | f Yellow = "\027[33m"
+    | f Normal = "\027[0m"
+
+  fun colorize color s = (f color) ^ s ^ (f Normal)
+
+  val redit = colorize Red
+
+  val greenit = colorize Green
+
+  val yellowit = colorize Yellow
+end
+
+structure Test =
+struct
+  datatype testnode = TestGroup of string * testnode list
+                    | Test of string * (unit -> Expect.expectation)
+
+  local
+    datatype evaluation = Success of string
+                        | Failure of string * string * string
+                        | Error of string * string
+
+    fun indent n s = (implode (List.tabulate (n, fn _ => #" "))) ^ s
+
+    fun fmt indentlvl ev =
+      let
+        val check = TermColor.greenit "\226\156\148 " (* ✔ *)
+        val cross = TermColor.redit "\226\156\150 "   (* ✖ *)
+        val indentlvl = indentlvl * 2
+      in
+      case ev of
+        Success descr => indent indentlvl (check ^ descr)
+      | Failure (descr, exp, got) =>
+          String.concatWith "\n" [indent indentlvl (cross ^ descr),
+                                  indent (indentlvl + 2) exp,
+                                  indent (indentlvl + 2) got]
+      | Error (descr, reason) =>
+          String.concatWith "\n" [indent indentlvl (cross ^ descr),
+                                  indent (indentlvl + 2) (TermColor.redit reason)]
+      end
+
+    fun eval (TestGroup _) = raise Fail "Only a 'Test' can be evaluated"
+      | eval (Test (descr, thunk)) =
+          (
+            case thunk () of
+              Expect.Pass   => ((1, 0, 0), Success descr)
+            | Expect.Fail (s, s') => ((0, 1, 0), Failure (descr, s, s'))
+          )
+          handle e => ((0, 0, 1), Error (descr, "Unexpected error: " ^ exnMessage e))
+
+    fun flatten depth testnode =
+      let
+        fun sum (x, y, z) (a, b, c) = (x + a, y + b, z + c)
+
+        fun aux (t, (counter, acc)) =
+          let
+            val (counter', texts) = flatten (depth + 1) t
+          in
+            (sum counter' counter, texts :: acc)
+          end
+      in
+        case testnode of
+          TestGroup (descr, ts) =>
+            let
+              val (counter, texts) = foldr aux ((0, 0, 0), []) ts
+            in
+              (counter, (indent (depth * 2) descr) :: List.concat texts)
+            end
+        | Test _ =>
+            let
+              val (counter, evaluation) = eval testnode
+            in
+              (counter, [fmt depth evaluation])
+            end
+      end
+    
+    fun println s = print (s ^ "\n")
+  in
+    fun run suite =
+      let
+        val ((succeeded, failed, errored), texts) = flatten 0 suite
+
+        val summary = String.concatWith ", " [
+          TermColor.greenit ((Int.toString succeeded) ^ " passed"),
+          TermColor.redit ((Int.toString failed) ^ " failed"),
+          TermColor.redit ((Int.toString errored) ^ " errored"),
+          (Int.toString (succeeded + failed + errored)) ^ " total"
+        ]
+        
+        val status = if failed = 0 andalso errored = 0
+                     then OS.Process.success
+                     else OS.Process.failure
+
+      in
+        List.app println texts;
+        println "";
+        println ("Tests: " ^ summary);
+        OS.Process.exit status
+      end
+  end
+end
+
+fun describe description tests = Test.TestGroup (description, tests)
+fun test description thunk = Test.Test (description, thunk)