Add std.process.Config.preExecDelegate

std.process.Config.preExecDelegate is just like
std.process.Config.preExecFunction, but can capture an environment, for
example:

    import core.sys.linux.sys.prctl : PR_SET_PDEATHSIG, prctl;
    import std.process : Config, execute;

    void runProgram(int pdeathsig)
    {
        execute(
            ["program"],
            config: Config(
                preExecDelegate: () @trusted =>
                    prctl(PR_SET_PDEATHSIG, pdeathsig, 0, 0, 0) != -1,
            ),
        );
    }

preExecFunction is retained for backwards compatibility. If both
preExecFunction and preExecDelegate are given, both are called.

Author: chloekek

changelog/std.process.Config.preExecDelegate.dd

@@ -0,0 +1,25 @@
+Add `std.process.Config.preExecDelegate`
+
+$(LINK2 $(ROOT_DIR)phobos/std_process.html#.Config.preExecDelegate, `std.process.Config.preExecDelegate`)
+is just like
+$(LINK2 $(ROOT_DIR)phobos/std_process.html#.Config.preExecFunction, `std.process.Config.preExecFunction`),
+but can capture an environment, for example:
+
+-------
+import core.sys.linux.sys.prctl : PR_SET_PDEATHSIG, prctl;
+import std.process : Config, execute;
+
+void runProgram(int pdeathsig)
+{
+    execute(
+        ["program"],
+        config: Config(
+            preExecDelegate: () @trusted =>
+                prctl(PR_SET_PDEATHSIG, pdeathsig, 0, 0, 0) != -1,
+        ),
+    );
+}
+-------
+
+`preExecFunction` is retained for backwards compatibility. If both
+`preExecFunction` and `preExecDelegate` are given, both are called.

changelog/std.process.Config.preExecFunction-delegate.dd

@@ -1102,6 +1102,14 @@ private Pid spawnProcessPosix(scope const(char[])[] args,
                 }
             }
 
+            if (config.preExecDelegate !is null)
+            {
+                if (config.preExecDelegate() != true)
+                {
+                    abortOnError(forkPipeOut, InternalError.preExec, .errno);
+                }
+            }
+
             // Execute program.
             core.sys.posix.unistd.execve(argz[0], argz.ptr, envz);
 
@@ -1187,7 +1195,7 @@ private Pid spawnProcessPosix(scope const(char[])[] args,
                     errorMsg = "Failed to allocate memory";
                     break;
                 case InternalError.preExec:
-                    errorMsg = "Failed to execute preExecFunction";
+                    errorMsg = "Failed to execute preExecFunction or preExecDelegate";
                     break;
                 case InternalError.noerror:
                     assert(false);
@@ -1272,18 +1280,25 @@ version (Posix)
 }
 
 version (Posix)
-@safe unittest
+@system unittest
 {
+    __gshared int j;
     foreach (i; 0 .. 3)
     {
         auto config = Config(
-            preExecFunction: delegate() @trusted {
-                _Exit(i);
+            preExecFunction: function() @trusted {
+                j = 1;
+                return true;
+            },
+            preExecDelegate: delegate() @trusted {
+                // j should now be 1, as preExecFunction is called before
+                // preExecDelegate is.
+                _Exit(i + j);
                 return true;
             },
         );
         auto pid = spawnProcess(["false"], config: config);
-        assert(wait(pid) == i);
+        assert(wait(pid) == i + 1);
     }
 }
 
@@ -2202,13 +2217,30 @@ struct Config
             Please note that the code in this function must only use
             async-signal-safe functions.)
 
+        If $(LREF preExecDelegate) is also set, it is called last.
+
+        On Windows, this member is not available.
+        */
+        bool function() nothrow @nogc @safe preExecFunction;
+
+        /**
+        A delegate that is called before `exec` in $(LREF spawnProcess).
+        It returns `true` if succeeded and otherwise returns `false`.
+
+        $(RED Warning:
+            Please note that the code in this function must only use
+            async-signal-safe functions.)
+
+        If $(LREF preExecFunction) is also set, it is called first.
+
         On Windows, this member is not available.
         */
-        bool delegate() nothrow @nogc @safe preExecFunction;
+        bool delegate() nothrow @nogc @safe preExecDelegate;
     }
     else version (Posix)
     {
-        bool delegate() nothrow @nogc @safe preExecFunction;
+        bool function() nothrow @nogc @safe preExecFunction;
+        bool delegate() nothrow @nogc @safe preExecDelegate;
     }
 }