Gracefully handle assertion errors during runtime startup/teardown

assert() is used throughout the various bits and pieces involved in
druntime startup and teardown. However, the default assert handler
(throwing an AssertError) requires the GC and exception handling to
be up and running, which is not the case for failures e.g. in the
module registry code.

Of course, these assertions should never be triggered in shipped
versions of druntime. But they might be during development, and
this change ensures that a sensible error message is printed
instead of hitting an infinite recursion or a GC deadlock.

Author: dnadlinger

src/core/exception.d

@@ -416,6 +416,21 @@ deprecated void setAssertHandler( AssertHandler h ) @trusted nothrow @nogc
     assertHandler = h;
 }
 
+private __gshared bool assertEHEnabled = false;
+extern(C) void _d_setAssertEHEnabled( bool enabled )
+{
+    assertEHEnabled = enabled;
+}
+
+private void defaultAssertHandler( string file, size_t line, string msg ) nothrow
+{
+    if ( assertEHEnabled )
+        throw msg ? new AssertError( msg, file, line ) : new AssertError( file, line );
+
+    import core.internal.abort;
+    abort( file, line, "Assertion failure during runtime startup/teardown",
+        msg ? ": " : ".", msg );
+}
 
 ///////////////////////////////////////////////////////////////////////////////
 // Overridable Callbacks
@@ -434,7 +449,7 @@ deprecated void setAssertHandler( AssertHandler h ) @trusted nothrow @nogc
 extern (C) void onAssertError( string file = __FILE__, size_t line = __LINE__ ) nothrow
 {
     if( _assertHandler is null )
-        throw new AssertError( file, line );
+        defaultAssertHandler( file, line, null );
     _assertHandler( file, line, null);
 }
 
@@ -452,7 +467,7 @@ extern (C) void onAssertError( string file = __FILE__, size_t line = __LINE__ )
 extern (C) void onAssertErrorMsg( string file, size_t line, string msg ) nothrow
 {
     if( _assertHandler is null )
-        throw new AssertError( msg, file, line );
+        defaultAssertHandler( file, line, msg );
     _assertHandler( file, line, msg );
 }
 

src/core/internal/abort.d

@@ -5,6 +5,11 @@ module core.internal.abort;
  * code, and druntime is -release compiled.
  */
 void abort(string msg, string filename = __FILE__, size_t line = __LINE__) @nogc nothrow @safe
+{
+    abort(filename, line, msg);
+}
+
+void abort(string filename, size_t line, const(char)[][] msgs...) @nogc nothrow @safe
 {
     import core.stdc.stdlib: c_abort = abort;
     // use available OS system calls to print the message to stderr
@@ -40,6 +45,7 @@ void abort(string msg, string filename = __FILE__, size_t line = __LINE__) @nogc
     UnsignedStringBuf strbuff;
 
     // write an appropriate message, then abort the program
-    writeStr("Aborting from ", filename, "(", line.unsignedToTempString(strbuff, 10), ") ", msg);
+    writeStr("Aborting from ", filename, "(", line.unsignedToTempString(strbuff, 10), "): ");
+    writeStr(msgs);
     c_abort();
 }

src/rt/dmain2.d

@@ -50,6 +50,7 @@ extern (C) void rt_moduleTlsDtor();
 extern (C) void thread_joinAll();
 extern (C) bool runModuleUnitTests();
 extern (C) void _d_initMonoTime();
+extern (C) void _d_setAssertEHEnabled(bool enabled);
 
 version (OSX)
 {
@@ -180,6 +181,7 @@ extern (C) int rt_init()
         initStaticDataGC();
         lifetime_init();
         rt_moduleCtor();
+        _d_setAssertEHEnabled(true);
         rt_moduleTlsCtor();
         return 1;
     }
@@ -205,6 +207,7 @@ extern (C) int rt_term()
     {
         rt_moduleTlsDtor();
         thread_joinAll();
+        _d_setAssertEHEnabled(false);
         rt_moduleDtor();
         gc_term();
         finiSections();