implement the fix from JuliaCI/LocalCoverage.jl#68

Author: disberd

Project.toml

@@ -1,13 +1,14 @@
 name = "ExtendedLocalCoverage"
 uuid = "eb248270-a497-541c-8f75-6bb2aa2715dc"
+version = "0.1.2"
 authors = ["Alberto Mengali <[email protected]>"]
-version = "0.1.1"
 
 [deps]
 CondaPkg = "992eb4ea-22a4-4c89-a5bb-47a3300528ab"
 CoverageTools = "c36e975a-824b-4404-a568-ef97ca766997"
 LocalCoverage = "5f6e1e16-694c-5876-87ef-16b5274f298e"
 Pkg = "44cfe95a-1eb2-52ea-b672-e2afdf69b78f"
+PrettyTables = "08abe8d2-0d0c-5749-adfa-8a2ac140af0d"
 PythonCall = "6099a3de-0909-46bc-b1f4-468b9a2dfc0d"
 Revise = "295af30f-e4ad-537b-8983-00126c2a3abe"
 TOML = "fa267f1f-6049-4f14-aa54-33bafae1ed76"
@@ -17,6 +18,7 @@ CondaPkg = "0.2.24"
 CoverageTools = "1.3.2"
 LocalCoverage = "0.8.2"
 Pkg = "1"
+PrettyTables = "2, 3"
 PythonCall = "0.9.23"
 Revise = "3.7.1"
 TOML = "1.0.3"

src/ExtendedLocalCoverage.jl

@@ -10,6 +10,9 @@ import Pkg
 
 export generate_package_coverage, generate_html_report
 
+# This is a temporary fix to fix PrettyTables issues until https://github.com/JuliaCI/LocalCoverage.jl/pull/68 is merged.
+include("show_fix.jl")
+
 function extract_package_info(pkg_dir)
     project_toml = TOML.tryparsefile(joinpath(pkg_dir, "Project.toml"))
     pkg_name = project_toml["name"]
@@ -105,7 +108,7 @@ function generate_package_coverage(pkg = nothing; use_existing_lcov = false, run
             return true
         end
         LocalCoverage.generate_coverage(pkg; run_test, test_args, folder_list=[], file_list)
-    end
+    end |> WrappedPackageCoverage
     if print_to_stdout
         show(IOContext(stdout, :print_gaps => true), cov)
     end

src/show_fix.jl

@@ -0,0 +1,89 @@
+using LocalCoverage: PackageCoverage, format_line
+using PrettyTables: PrettyTables, pretty_table
+
+"""
+    WrappedPackageCoverage(summary::PackageCoverage)
+
+Structure wrapping the `PackageCoverage` struct to add a custom `show` method for fixing PrettyTables issues until https://github.com/JuliaCI/LocalCoverage.jl/pull/68 is merged.
+"""
+struct WrappedPackageCoverage
+    summary::PackageCoverage
+end
+
+function Base.show(io::IO, wrapped::WrappedPackageCoverage)
+    (; summary) = wrapped
+    (; files, package_dir) = summary
+    row_data = map(format_line, files)
+    push!(row_data, format_line(summary))
+    row_coverage = map(x -> x.coverage_percentage, row_data)
+    rows = map(row_data) do row
+        (; name, total, hit, missed, coverage_percentage, gaps) = row
+        percentage = isnan(coverage_percentage) ? "-" : "$(round(Int, coverage_percentage))%"
+        (; name, total, hit, missed, percentage, gaps)
+    end
+    header = ["Filename", "Lines", "Hit", "Miss", "%"]
+    percentage_column = length(header)
+    alignment = [:l, :r, :r, :r, :r]
+    columns_width = fill(-1, 5) # We need strictly negative number to autosize in PrettyTables 3.0, but this also works in v2
+    if get(io, :print_gaps, false)
+        push!(header, "Gaps")
+        push!(alignment, :l)
+        display_cols = last(get(io, :displaysize, 100))
+        push!(columns_width, display_cols - 45)
+    else
+        rows = map(row -> Base.structdiff(row, NamedTuple{(:gaps,)}), rows)
+    end
+    # PrettyTables 3.0 changed Highlighter to TextHighlighter, which up to currently published version (v3.10) does not provide the kwargs constructor (despite having it documented). We create here a patch to handle both cases
+    Highlighter(f; kwargs...) = @static if pkgversion(PrettyTables) < v"3.0.0"
+        PrettyTables.Highlighter(f; kwargs...)
+    else
+        PrettyTables.TextHighlighter(f, PrettyTables.Crayon(;kwargs...))
+    end
+
+    highlighters = (
+        Highlighter(
+            (data, i, j) -> j == percentage_column && row_coverage[i] <= 50,
+            bold = true,
+            foreground = :red,
+        ),
+        Highlighter((data, i, j) -> j == percentage_column && row_coverage[i] <= 70,
+                    foreground = :yellow),
+        Highlighter((data, i, j) -> j == percentage_column && row_coverage[i] >= 90,
+                    foreground = :green),
+    )
+
+    # Kwargs of `pretty_table` itself also changed in PrettyTables 3.0, so we have to branch here as well
+    @static if pkgversion(PrettyTables) < v"3.0.0"
+        pretty_table(
+            io,
+            rows;
+            title = "Coverage of $(package_dir)",
+            header,
+            alignment,
+            crop = :none,
+            linebreaks = true,
+            columns_width,
+            autowrap = true,
+            highlighters,
+            body_hlines = [length(rows) - 1],
+        )
+    else
+        pretty_table(
+            io,
+            rows;
+            title = "Coverage of $(package_dir)",
+            column_labels = [header],
+            alignment,
+            # The crop kwarg is not present anymore, split into the next two ones
+            fit_table_in_display_horizontally = false,
+            fit_table_in_display_vertically = false,
+            line_breaks = true,
+            fixed_data_column_widths = columns_width,
+            auto_wrap = true,
+            highlighters = collect(highlighters), # v3 expects a vector instead of a Tuple
+            table_format = PrettyTables.TextTableFormat(;
+                horizontal_lines_at_data_rows = [length(rows) - 1],
+            ),
+        )
+    end
+end