justfile

default:
    @just --list

# Prefer nextest if installed; fall back to cargo test.
test:
    if command -v cargo-nextest >/dev/null 2>&1; then cargo nextest run; else cargo test; fi

check:
    cargo fmt --all -- --check
    cargo clippy --all-targets -- -D warnings
    just test

docs:
    RUSTDOCFLAGS="-D warnings --html-in-header docs/katex-header.html" cargo doc --all-features --no-deps
    @echo "Docs generated at: target/doc/subsume/index.html"

docs-open: docs
    if command -v open >/dev/null 2>&1; then open target/doc/subsume/index.html; \
    elif command -v xdg-open >/dev/null 2>&1; then xdg-open target/doc/subsume/index.html; \
    elif command -v start >/dev/null 2>&1; then start target/doc/subsume/index.html; \
    else echo "Open: target/doc/subsume/index.html"; fi

docs-watch:
    RUSTDOCFLAGS="-D warnings --html-in-header docs/katex-header.html" cargo watch -x "doc --all-features --no-deps"

clqa-eval MODE="box":
    ./scripts/run_clqa_eval.sh "{{MODE}}"

typst-docs:
    ./docs/typst/build.sh

typst-preview FILE:
    if [[ -z "{{FILE}}" ]]; then echo "Usage: just typst-preview <filename>"; exit 1; fi
    ./docs/typst/preview.sh "{{FILE}}"