ImageFrameMDE/build.gradle at main · Zone-Infinity/ImageFrameMDE · GitHub

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
plugins {
    id 'java'
    id("xyz.jpenilla.run-paper") version "2.3.1"
    id("io.github.goooler.shadow") version "8.1.7"
}

group = 'me.isoham.imageframe.mde'
version = '1.0'

repositories {
    mavenCentral()
    maven {
        name = "spigotmc-repo"
        url = "https://hub.spigotmc.org/nexus/content/repositories/snapshots/"
    }
    maven { url = 'https://repo.loohpjames.com/repository' }
}

dependencies {
    compileOnly("org.spigotmc:spigot-api:1.21-R0.1-SNAPSHOT")
    compileOnly("com.loohp:ImageFrame:1.8.7.4")

    implementation("net.dv8tion:JDA:6.3.2") {
        exclude module: "opus-java"
        exclude module: "tink"
    }

    implementation("org.xerial:sqlite-jdbc:3.46.0.0")
}

tasks {

    shadowJar {
        archiveClassifier.set("")

        relocate "net.dv8tion.jda", "me.isoham.imageframe.mde.libs.jda"
        relocate "okhttp3", "me.isoham.imageframe.mde.libs.okhttp"
        relocate "okio", "me.isoham.imageframe.mde.libs.okio"
        relocate "com.fasterxml.jackson", "me.isoham.imageframe.mde.libs.jackson"

        mergeServiceFiles()

        exclude("org/sqlite/native/**")
        exclude("META-INF/*.SF")
        exclude("META-INF/*.DSA")
        exclude("META-INF/*.RSA")
    }

    build {
        dependsOn(shadowJar)
    }

    runServer {
        minecraftVersion("1.21.11")
    }
}

def targetJavaVersion = 21

java {
    toolchain.languageVersion = JavaLanguageVersion.of(targetJavaVersion)
}

tasks.withType(JavaCompile).configureEach {
    options.encoding = "UTF-8"
    options.release.set(targetJavaVersion)
}

processResources {
    def props = [version: version]
    inputs.properties props
    filteringCharset 'UTF-8'

    filesMatching('plugin.yml') {
        expand props
    }
}