Merge pull request #283 from PolyMathOrg/refactor-quaternions

Refactor: Quaternion multiplication

Author: SergeStinckwich

src/Math-Quaternion/Number.extension.st

@@ -41,3 +41,8 @@ Number >> k [
 		qj: 0
 		qk: self
 ]
+
+{ #category : #'*Math-Quaternion' }
+Number >> multiplyByQuaternion: quaternion [
+	^ quaternion timesNumber: self.
+]

src/Math-Quaternion/PMComplexNumber.extension.st

@@ -36,3 +36,9 @@ PMComplexNumber >> k [
 		qj: imaginary negated
 		qk: real
 ]
+
+{ #category : #'*Math-Quaternion' }
+PMComplexNumber >> multiplyByQuaternion: quaternion [
+
+	^ quaternion timesComplexNumber: self
+]

src/Math-Quaternion/PMPolynomial.extension.st

@@ -4,3 +4,9 @@ Extension { #name : #PMPolynomial }
 PMPolynomial >> adaptToQuaternion: rcvr andSend: selector [
 	^(self class coefficients: (Array with: rcvr) ) perform: selector with: self
 ]
+
+{ #category : #'*Math-Quaternion' }
+PMPolynomial >> multiplyByQuaternion: quaternion [
+
+	^ (self class coefficients: (Array with: quaternion)) * self
+]

src/Math-Quaternion/PMQuaternion.class.st

@@ -78,29 +78,12 @@ PMQuaternion class >> zero [
 ]
 
 { #category : #arithmetic }
-PMQuaternion >> * aQuaternion [ 
+PMQuaternion >> * multiplier [
+
 	"Answer the result of multiplying self with aQuaternion.
 	Distribute the product (qr + qi i +qj j + qk k)*(tr+ti i + tj j + tk k)
 	with rules i*i=j*j=k*k=-1 and i*j=-k, j*k=-i, k*i=-j"
-	^ aQuaternion isQuaternion
-		ifTrue: [| tr ti tj tk | 
-			tr := aQuaternion qr.
-			ti := aQuaternion qi.
-			tj := aQuaternion qj.
-			tk := aQuaternion qk.
-			^ self species
-				qr: qr * tr - (qi * ti) - (qj * tj) - (qk * tk)
-				qi: qr * ti + (qi * tr) + (qj * tk) - (qk * tj)
-				qj: qr * tj + (qj * tr) + (qk * ti) - (qi * tk)
-				qk: qr * tk + (qk * tr) + (qi * tj) - (qj * ti)]
-		ifFalse: [(aQuaternion isNumber and: [aQuaternion isComplexNumber not])
-				ifTrue: ["handle case much faster than adapt..."
-					self species
-						qr: qr * aQuaternion
-						qi: qi * aQuaternion
-						qj: qj * aQuaternion
-						qk: qk * aQuaternion]
-				ifFalse: [aQuaternion adaptToQuaternion: self andSend: #*]]
+	^ multiplier multiplyByQuaternion: self.
 ]
 
 { #category : #arithmetic }
@@ -372,6 +355,22 @@ PMQuaternion >> log [
 	^self ln / 10 ln
 ]
 
+{ #category : #arithmetic }
+PMQuaternion >> multiplyByQuaternion: multiplier [
+
+	| tr ti tj tk |
+	tr := multiplier qr.
+	ti := multiplier qi.
+	tj := multiplier qj.
+	tk := multiplier qk.
+
+	^ self species
+		  qr: tr * qr - (ti * qi) - (tj * qj) - (tk * qk)
+		  qi: tr * qi + (ti * qr) + (tj * qk) - (tk * qj)
+		  qj: tr * qj - (ti * qk) + (tj * qr) + (tk * qi)
+		  qk: tr * qk + (tk * qr)- (tj * qi) + (ti * qj)
+]
+
 { #category : #arithmetic }
 PMQuaternion >> negated [
 	^self species 
@@ -591,6 +590,25 @@ PMQuaternion >> tanh [
 	^(ep - em) / (ep + em)
 ]
 
+{ #category : #arithmetic }
+PMQuaternion >> timesComplexNumber: complexNumber [
+
+	| x y |
+	x := complexNumber real.
+	y := complexNumber imaginary.
+
+	^ self species
+		  qr: x * qr - (y * qi)
+		  qi: x * qi + (y * qr)
+		  qj: x * qj + (y * qk)
+		  qk: x * qk - (y * qj)
+]
+
+{ #category : #arithmetic }
+PMQuaternion >> timesNumber: multiplier [
+	^ self class qr: (qr * multiplier) qi: (qi * multiplier) qj: (qj * multiplier)  qk: (qk * multiplier).
+]
+
 { #category : #'*Math-Quaternion' }
 PMQuaternion >> timesPolynomial: aPolynomial [
 	^aPolynomial timesNumber: self

src/Math-Quaternion/PMVector.extension.st

@@ -4,3 +4,9 @@ Extension { #name : #PMVector }
 PMVector >> adaptToQuaternion: aQuaternion andSend: aByteSymbol [
 	^ self collect: [ :ea | aQuaternion perform: aByteSymbol with: ea ]
 ]
+
+{ #category : #'*Math-Quaternion' }
+PMVector >> multiplyByQuaternion: quaternion [
+
+	^ self * quaternion.
+]

src/Math-Tests-Quaternion/PMQuaternionTest.class.st

@@ -84,6 +84,13 @@ PMQuaternionTest >> testDividePolynomial [
 	self assert: ((poly / q12) coefficients allSatisfy: [ :ea | ea = 1 ])
 ]
 
+{ #category : #running }
+PMQuaternionTest >> testDivision [
+	self assert: (0 / q1234) isZero.
+	self assert: 1 / q1234 equals: q1234 reciprocal.
+	self assert: q1234 / q1234 equals: 1
+]
+
 { #category : #running }
 PMQuaternionTest >> testEquality [
 	self assert: q1234 equals: q1234 copy.
@@ -153,6 +160,103 @@ PMQuaternionTest >> testLog [
 	self assert: (qln qk closeTo: qlg10ln qk)
 ]
 
+{ #category : #'testing - arithmetic' }
+PMQuaternionTest >> testMultiplicationByComplexNumberIsNonCommutative [
+	| quaternion complexNumber |
+	quaternion := 2 + 3 i + 4 j + 5 k.
+	complexNumber := 1 - 1 i.
+	
+	self assert: (quaternion * complexNumber) equals: 5 + 1 i - 1 j + 9 k.
+	self assert: (complexNumber * quaternion) equals: 5 + 1 i + 9 j + 1 k.
+]
+
+{ #category : #'testing - arithmetic' }
+PMQuaternionTest >> testMultiplicationByConjugate [
+
+	| quaternion |
+	quaternion := 1 + 2 i + 3 j + 4 k.
+	self assert: quaternion * (quaternion conjugated) equals: 30
+]
+
+{ #category : #'testing - arithmetic' }
+PMQuaternionTest >> testMultiplicationByIntegersIsCommutative [
+
+	| quaternion |
+	quaternion := 1 + 2 i + 3 j + 4 k.
+
+	self assert: quaternion * 5 equals: 5 + 10 i + 15 j + 20 k.
+	self assert: 5 * quaternion equals: 5 + 10 i + 15 j + 20 k.
+]
+
+{ #category : #'testing - arithmetic' }
+PMQuaternionTest >> testMultiplicationByPolynomialIsCommutative [
+
+	| poly quaternion |
+	poly := PMPolynomial coefficients: #( 1 1 1 ).
+	quaternion := 1 + 2 i + 0 j + 0 k.
+	self assert: (poly * quaternion at: 0) equals: q12.
+	self assert: (quaternion * poly at: 0) equals: q12
+]
+
+{ #category : #tests }
+PMQuaternionTest >> testMultiplicationByTheBasisElements [
+
+	| quaternion |
+	quaternion := 1 + 2 i + 3 j + 4 k.
+	
+	self assert: quaternion * 1 i equals: (-2 + 1 i + 4 j - 3 k).
+	self assert: quaternion * 1 j equals: (-3 - 4 i + 1 j + 2 k).
+	self assert: quaternion * 1 k equals: (-4 + 3 i - 2 j + 1 k)
+]
+
+{ #category : #'testing - arithmetic' }
+PMQuaternionTest >> testMultiplicationByVectorIsCommutative [
+	| vec quaternion |
+	vec := PMVector new: 2.
+	vec at: 1 put: 1.
+	vec at: 2 put: 2.
+	quaternion := 1 + 2 i + 3 j + 4 k.
+	"This uses productWithVector"
+	self assert: (vec * quaternion at: 1) equals: (1 + 2 i + 3 j + 4 k).
+	self assert: (vec * quaternion at: 2) equals: (2 + 4 i + 6 j + 8 k).
+
+	"This uses adaptToQuaternion:andSend:"
+	self assert: (quaternion * vec at: 1) equals: 1 + 2 i + 3 j + 4 k.
+	self assert: (quaternion * vec at: 2) equals: 2 + 4 i + 6 j + 8 k.
+]
+
+{ #category : #'testing - arithmetic' }
+PMQuaternionTest >> testMultiplicationByZero [
+	| quaternion |
+	quaternion := 1 + 2 i + 3 j + 4 k.
+	
+	self assert: quaternion * 0 equals: 0 + 0 i + 0 j + 0 k.
+]
+
+{ #category : #'testing - arithmetic' }
+PMQuaternionTest >> testMultiplicationOfBasisElements [
+"https://en.wikipedia.org/wiki/Quaternion#Multiplication_of_basis_elements"
+
+	self assert: 1 i * 1 i equals: -1.
+	self assert: 1 j * 1 j equals: -1.
+	self assert: 1 k * 1 k equals: -1.
+	self assert: 1 i * 1 j equals: 1 k.
+	self assert: 1 j * 1 k equals: 1 i.
+	self assert: 1 k * 1 i equals: 1 j.
+	self assert: 1 j * 1 i equals: -1 k.
+	self assert: 1 k * 1 j equals: -1 i.
+	self assert: 1 i * 1 k equals: -1 j.
+	self assert: 1 i i equals: -1.
+	self assert: 1 j j equals: -1.
+	self assert: 1 k k equals: -1.
+	self assert: 1 i j equals: 1 k.
+	self assert: 1 j k equals: 1 i.
+	self assert: 1 k i equals: 1 j.
+	self assert: 1 j i equals: -1 k.
+	self assert: 1 k j equals: -1 i.
+	self assert: 1 i k equals: -1 j.
+]
+
 { #category : #running }
 PMQuaternionTest >> testNaturalLogOfQuaternion [
 
@@ -227,51 +331,6 @@ PMQuaternionTest >> testPrintOn [
 	self assert: s equals: '(1 i: 2 j: 3 k: 4)'
 ]
 
-{ #category : #running }
-PMQuaternionTest >> testProduct [
-	self assert: q1234 * 5 equals: (5 i: 10 j: 15 k: 20).
-	self assert: 5 * q1234 equals: (5 i: 10 j: 15 k: 20).
-	self assert: 1 i * 1 i equals: -1.
-	self assert: 1 j * 1 j equals: -1.
-	self assert: 1 k * 1 k equals: -1.
-	self assert: 1 i * 1 j equals: 1 k.
-	self assert: 1 j * 1 k equals: 1 i.
-	self assert: 1 k * 1 i equals: 1 j.
-	self assert: 1 j * 1 i equals: -1 k.
-	self assert: 1 k * 1 j equals: -1 i.
-	self assert: 1 i * 1 k equals: -1 j.
-	self assert: 1 i i equals: -1.
-	self assert: 1 j j equals: -1.
-	self assert: 1 k k equals: -1.
-	self assert: 1 i j equals: 1 k.
-	self assert: 1 j k equals: 1 i.
-	self assert: 1 k i equals: 1 j.
-	self assert: 1 j i equals: -1 k.
-	self assert: 1 k j equals: -1 i.
-	self assert: 1 i k equals: -1 j.
-	self assert: q1234 * 1 i equals: q1234 i.
-	self assert: q1234 * 1 j equals: q1234 j.
-	self assert: q1234 * 1 k equals: q1234 k.
-	self assert: (q1234 * 0) isZero.
-	self assert: (0 / q1234) isZero.
-	self assert: q1234 * q1234 conjugated equals: q1234 squaredNorm.
-	self assert: 1 / q1234 equals: q1234 reciprocal.
-	self assert: q1234 / q1234 equals: 1
-]
-
-{ #category : #running }
-PMQuaternionTest >> testProductWithVector [
-	| vec |
-	vec := PMVector new: 2.
-	vec at: 1 put: 1.
-	vec at: 2 put: 2.
-	"This uses productWithVector"
-	self assert: (vec * q1234 at: 2) equals: 2 * q1234.
-
-	"This uses adaptToQuaternion:andSend:"
-	self assert: (q1234 * vec at: 1) equals: q1234
-]
-
 { #category : #running }
 PMQuaternionTest >> testRaisedTo [
 	| eps |
@@ -363,14 +422,6 @@ PMQuaternionTest >> testTanh [
 	self assert: ((1 + 2 i) tanh - (1 + 2 j k) tanh) abs < eps
 ]
 
-{ #category : #running }
-PMQuaternionTest >> testTimesPolynomial [
-	| poly |
-	poly := PMPolynomial coefficients: #(1 1 1).
-	self assert: (poly * q12 at: 0) equals: q12.
-	self assert: (q12 * poly at: 0) equals: q12
-]
-
 { #category : #running }
 PMQuaternionTest >> testUnreal [
 	self assert: q1234 unreal real equals: 0.