Will we consider maintaining only OpenGL shader files, such as triangle. vert and triangle. frag, in the future, and automatically converting them into Vulkan shader code when the code runs

[Haidiye00]

Will we consider maintaining only OpenGL shader files, such as triangle. vert and triangle. frag, in the future, and automatically converting them into Vulkan shader code when the code runs

[LukasBanana]

The short answer is: No.

But let's dive a bit deeper into this. For the LLGL examples, I have indeed an inconvenient workflow for shaders as I'm mostly handwriting the Vulkan versions of the GLSL shaders and then compile them to SPIR-V with the CompileGlslToSpirv.bat script. I'm doing this by hand mostly because these shaders are so small, that I don't really care about scripts to do full cross-compilation from HLSL to all other languages as this comes with its own type of maintenance. That being said, as the number of tests and examples are increasing, I might integrate some scripts I wrote for side projects to do this cross-compilation a bit more automatically.

Besides the handwritten Vulkan shaders, it sounds like you're asking to integrate GLSL to SPIR-V compilation into the runtime of LLGL. For this I'd like to reiterate on something which I consciously decided against:
LLGL is meant as a rendering API abstraction first and foremost. Any tooling to provide the data you feed into LLGL in a cross-platform manner is not part of LLGL's responsibility. There is very little to simplify the shader compilation at runtime to make iterating on tests and prototypes easier, such as compiling HLSL from source instead of bytecode. Those exist solely for convenience, but once your project reaches a certain size, it is recommended that you have an external pipeline (either through CMake or other tools) that transforms your shaders into the most efficient form for the respective runtime API, i.e. DXBC or DXIL for the D3D backends, SPIR-V for Vulkan, AIR (Apple IR) for Metal, and sadly GLSL source for OpenGL because there's no alternative for this backend.
Supporting your request to feed GLSL source into the Vulkan backend requires to integrate either glslang or DXC into LLGL or at least make it an external dependency, but I'd like to keep the external dependencies as small as possible. I know other rendering abstraction libraries support this type of cross-compilation, either through those compilers or via their own parsers. That comes at the cost of either higher dependency or custom parsers with partial/fragile HLSL support.
LLGL currently references DXC dynamically (see Renderer/DXCommon/DXC/), but that only loads the dxcompiler.dll on Windows to support runtime compilation of HLSL to DXIL for D3D12. Perhaps this can be extended in the future to also support HLSL to SPIR-V compilation, but this code is currently Windows only and intended solely for the D3D12 backend.

If you're interested, I can share a snippet from my project I am trying to finalize for the longest time but it's an on and off thing. I compile all shaders with a single batch script which is calling a Python script to patch up the GLSL output. This looks something like this:

if "%1"=="-d" (
    set /A GENERATE_DEBUG_INFO=1
) else (
    set /A GENERATE_DEBUG_INFO=0
)

set SPIRVCROSS_BASE_OPTIONS=--combined-samplers-inherit-bindings --no-support-nonzero-baseinstance --relax-nan-checks

set FXC="fxc"
set DXC="dxc"

call :CompileShader GaussianBlur PSMain ps frag
...

:CompileShader

set SHADER=%~1
set ENTRY=%~2
set PROFILE_SM5=%~3_5_0
set PROFILE_SM6=%~3_6_0
set GLTARGET=%~4

echo Compile DXBC\%SHADER%.%ENTRY%.dxbc
%FXC% /nologo /I ..\..\ /E %ENTRY% /T %PROFILE_SM5% /Fo DXBC\%SHADER%.%ENTRY%.dxbc /Fc DXBC\DebugSymbols\%SHADER%.%ENTRY%.opt.txt %SHADER%.hlsl
if %GENERATE_DEBUG_INFO% NEQ 0 (
    %FXC% /nologo /I ..\..\ /E %ENTRY% /T %PROFILE_SM5% /O0 /Zi /Fc DXBC\DebugSymbols\%SHADER%.%ENTRY%.deb.txt /Fd DXBC\DebugSymbols\%SHADER%.%ENTRY%.pdb %SHADER%.hlsl
)

echo Compile DXIL\%SHADER%.%ENTRY%.dxil
%DXC% -nologo -I ..\..\ -E %ENTRY% -T %PROFILE_SM6% -Fo DXIL\%SHADER%.%ENTRY%.dxil -Fc DXIL\DebugSymbols\%SHADER%.%ENTRY%.opt.txt %SHADER%.hlsl
if %GENERATE_DEBUG_INFO% NEQ 0 (
    %DXC% -nologo -I ..\..\ -E %ENTRY% -T %PROFILE_SM6% -O0 -Zi -Fc DXIL\DebugSymbols\%SHADER%.%ENTRY%.deb.txt -Fd DXIL\DebugSymbols\%SHADER%.%ENTRY%.pdb %SHADER%.hlsl
)

echo Compile SPIRV\%SHADER%.%ENTRY%.spv
%DXC% -nologo -spirv -I ..\..\ -E %ENTRY% -T %PROFILE_SM6% -Fo SPIRV\%SHADER%.%ENTRY%.spv %SHADER%.hlsl
if %GENERATE_DEBUG_INFO% NEQ 0 (
    spirv-dis --comment -o SPIRV\DebugSymbols\%SHADER%.%ENTRY%.spvasm SPIRV\%SHADER%.%ENTRY%.spv
)

echo Compile GLSL\%SHADER%.%ENTRY%.%GLTARGET%
spirv-cross %SPIRVCROSS_BASE_OPTIONS% --output GLSL\%SHADER%.%ENTRY%.%GLTARGET%.unpatched SPIRV\%SHADER%.%ENTRY%.spv
python ..\PatchGlslShader.py GLSL\%SHADER%.%ENTRY%.%GLTARGET%.unpatched > GLSL\%SHADER%.%ENTRY%.%GLTARGET%
del GLSL\%SHADER%.%ENTRY%.%GLTARGET%.unpatched

echo Compile Metal\%SHADER%.%ENTRY%.metal
spirv-cross %SPIRVCROSS_BASE_OPTIONS% --msl --output Metal\%SHADER%.%ENTRY%.metal SPIRV\%SHADER%.%ENTRY%.spv

exit /B 0

The Python script I'm running to patch the GLSL into a form that works with my runtime pipeline (i.e. making all fields of the $Globals cbuffer individual uniform declarations) looks like this:

#
# PatchGlslShader.py
#
# Copyright (c) 2023 Lukas Hermanns. All rights reserved.
# Licensed under the terms of the BSD 3-Clause license (see LICENSE.txt).
#

# Converts $Globals cbuffer declaration into global uniforms by removing "type_Globals" UBO declaration and all "_Globals." occurances
# Usage: PatchGlslShader.py FILE

import sys

if len(sys.argv) < 2:
    print('Usage: PatchGlslShader.py FILE')
    exit(1)

filename = sys.argv[1]

with open(filename, 'r') as file:
    isInsideGlobalsUBO = False
    for line in file:
        # Remove _Global. prefix
        line = line.replace('_Globals.', '')

        # Make tessellation control shader use 'odd spacing'
        line = line.replace('layout(quads) in', 'layout(quads, fractional_odd_spacing, ccw) in')

        # Convert UBO fields of $Globals cbuffer to individual uniforms
        if isInsideGlobalsUBO:
            if '{' in line:
                line = line.replace('{', '/* UNIFORMS */')
            elif '}' in line:
                endOfBlock = line.find('}')
                endOfDecl = line.find(';', endOfBlock + 1)
                line = '/* /UNIFORMS */' + line[endOfDecl+1:]
                isInsideGlobalsUBO = False
            else:
                line = f'uniform {line.lstrip()}' # Convert UBO field to individual uniform
            print(line, end='')
        elif 'uniform type_Globals' in line:
            isInsideGlobalsUBO = True
        else:
            print(line, end='')

I hope this helps. Let me know if you need any help finding a workflow or tools pipeline that simplifies this for you.
Laura