MWChartsPlugin-Android/build.gradle.kts at main · FutureWorkshops/MWChartsPlugin-Android · GitHub

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
// Top-level build file where you can add configuration options common to all sub-projects/modules.

if (project.rootProject.file("../gradle_files/common.gradle.kts").exists()) {
    apply("../gradle_files/common.gradle.kts")
}

buildscript {
    val kotlinVersion by extra("1.8.0")
    repositories {
        google()
        mavenCentral()
    }
    dependencies {
        classpath("com.android.tools.build:gradle:8.11.0")
        classpath("org.jetbrains.kotlin:kotlin-gradle-plugin:$kotlinVersion")
    }
}

allprojects {
    repositories {
        google()
        mavenCentral()
        maven { url = uri("https://jitpack.io") }

        maven {
            name = "Local maven"
            setUrl(project.rootProject.file("../MobileWorkflowCore-Android-Distribution").path)
        }

        maven {
            name = "Mobile Workflow"
            url = uri("https://raw.githubusercontent.com/FutureWorkshops/MobileWorkflowCore-Android-Distribution/main")
            credentials(HttpHeaderCredentials::class) {
                val token = (getProperty("project.githubPAT") as? String)
                    ?: System.getenv("GITHUB_PAT") ?: ""
                name = "Authorization"
                value = "token $token"
            }
            authentication {
                create<HttpHeaderAuthentication>("header")
            }
        }
    }
}

fun getProperty(property: String): Any? {
    val local = java.util.Properties()
    if (project.rootProject.file("local.properties").exists()) {
        local.load(project.rootProject.file("local.properties").inputStream())
    }
    return when {
        local.containsKey(property) -> local.getProperty(property)
        project.hasProperty(property) -> project.property(property)
        else -> null
    }
}