pine/build.gradle at master · AndroidStudioIst/pine · GitHub

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
// Top-level build file where you can add configuration options common to all sub-projects/modules.

// Load local.properties into gradle
def localProperties = new Properties()
def ins = rootProject.file('local.properties').newDataInputStream()
localProperties.load(ins)
ins.close()

buildscript {
    repositories {
		mavenLocal()
        google()
        mavenCentral()
        jcenter()
    }
    dependencies {
        classpath 'com.android.tools.build:gradle:7.4.1'

        // NOTE: Do not place your application dependencies here; they belong
        // in the individual module build.gradle files
    }
}

allprojects {
    localProperties.forEach { key, value -> setProperty(key, value) }

    repositories {
		mavenLocal()
        google()
        mavenCentral()
        jcenter()
    }

    task publishAarToSonatype(type: GradleBuild) {
        tasks = [
                'build',
                'publishMavenJavaPublicationToOssrhRepository'
        ]
    }
}

ext {
    compileSdkVersion = 33
    buildToolsVersion = "33.0.2"
    ndkVersion = "23.1.7779620"
    cmakeVersion = "3.18.1"
    userOrg = 'canyie'
    groupId = 'top.canyie.pine'
    repoName = 'pine'
    website = "https://github.com/canyie/pine"
}

ext.uploadRepositories = {
    maven {
        name 'ossrh'
        url 'https://s01.oss.sonatype.org/service/local/staging/deploy/maven2/'
        credentials {
            username localProperties['sonatypeUsername']
            password localProperties['sonatypePassword']
        }
    }
}

ext.licenses = {
    license {
        name = 'Anti 996 License Version 1.0'
        url = 'https://github.com/996icu/996.ICU/blob/master/LICENSE'
    }
}

ext.scm = {
    connection = 'scm:git:https://github.com/canyie/pine.git'
    url = 'https://github.com/canyie/pine'
}

ext.developers = {
    developer {
        name = 'canyie'
        url = 'https://github.com/canyie'
    }
}

task clean(type: Delete) {
    delete rootProject.buildDir
}