baseAndroid.gradle

/**
 * This gradle file contains the basic project configuration that all modules should use
 */
apply from: "$rootDir/baseExt.gradle"

apply plugin: 'kotlin-android'
apply plugin: 'kotlin-kapt'
apply plugin: 'kotlin-android-extensions'

android {
    compileSdkVersion versions.compileSdkVersion

    defaultConfig {
        minSdkVersion versions.minSdkVersion
        targetSdkVersion versions.targetSdkVersion
        versionCode versions.versionCode
        versionName versions.versionName
        testInstrumentationRunner versions.testInstrumentationRunner
        multiDexEnabled versions.multiDexEnabled
    }

    sourceSets {
        main.java.srcDirs += 'src/main/kotlin'
    }

    /**
     * We dont want to store the UT results anywhere, this is going to speed up the build process
     */
    testOptions.unitTests.all {
        reports.html.enabled = false
        reports.junitXml.enabled = false
        maxParallelForks = 7 //Speeds up yhe UT by running'em into 7 different forks
    }

    dexOptions {
        javaMaxHeapSize "4g"
        preDexLibraries = true
    }

    packagingOptions {
        exclude 'META-INF/rxjava.properties'
    }

    /**
     * This two options are basically disabling the lint validation during building time, we may want
     * to enable them from time to time, to check on the lint errors
     */
    lintOptions {
        tasks.lint.enabled = false
        abortOnError false
    }

    /**
     * Speeds up the building time
     */
    kapt {
        useBuildCache = true
    }

    compileOptions {
        incremental = true //Enables incremental builds so we don't need to rebuild unchanged modules
    }

    androidExtensions {
        experimental = true //Enables @Parcelize and other extensions
    }

    dataBinding.enabled = true
}